Change number of characters that can be typed, pasted or streamed in as Rich Text Format
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetLimitOnText ( $hWnd, $iNewLimit )
| $hWnd | Handle to the control |
| $iNewLimit | new limit |
| Success: | True. |
| Failure: | False and sets the @error flag to non-zero. |
| @error: | 101 - $hWnd is not a handle 102 - $iNewLimit is neither a positive number nor zero |
This function sets the limit on the number of characters a user can type in or paste into a control.
It also limits the number of characters of RTF text that can be streamed in using
_GUICtrlRichEdit_StreamFromFile() and _GUICtrlRichEdit_StreamFromVar().
It does not limit the amount of plain text that can be streamed in.
The initial limit is 32,767 characters.
_GUICtrlRichEdit_StreamFromFile, _GUICtrlRichEdit_StreamFromVar, _GUICtrlRichEdit_StreamToFile, _GUICtrlRichEdit_StreamToVar
Search EM_EXLIMITTEXT in MSDN Library.
#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>
Example()
Func Example()
Local $hGui, $iMsg, $idBtnNext, $iStep = 0
Local $idLblMsg, $hRichEdit
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$idBtnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState(@SW_SHOW)
_GUICtrlRichEdit_SetText($hRichEdit, "Paragraph 1")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($hRichEdit) ; needed unless script crashes
; GUIDelete() ; is OK too
Exit
Case $iMsg = $idBtnNext
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_SetLimitOnText($hRichEdit, 0)
GUICtrlSetData($idLblMsg, "1. Limit set to 65,536 characters")
Case 2
_GUICtrlRichEdit_SetLimitOnText($hRichEdit, 100000)
GUICtrlSetData($idLblMsg, "2. Limit set to 100,000 characters")
GUICtrlSetState($idBtnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Example