Function Reference


_GUICtrlRichEdit_StreamToVar

Writes contents of a control to a variable

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_StreamToVar ( $hWnd [, $bRtf = True [, $bIncludeCOM = True [, $iOpts = 0 [, $iCodePage = 0]]]] )

Parameters

$hWnd Handle to the control
$bRtf [optional] True - write Rich Text Format (RTF) (Default)
False - write only text
$bIncludeCOM [optional] True (default):
    If writing RTF, include any COM objects (space consuming)
    If writing only text, write a text represntation of COM objects
False: Write spaces instead of COM objects
$iOpts [optional] additional options:
    $SFF_PLAINRTF - write only rich text keywords common to all languages
    $SF_UNICODE - write Unicode
$iCodePage [optional] Generate UTF-8 and text using this code page
Default: do not

Return Value

Success: the RTF or text.
Failure: "" and sets the @error flag to non-zero.
@error: 101 - $hWnd is not a handle
1041 - $SFF_PLAINRTF is invalid for a text file
1042 - $opts: invalid option
1043 - $SF_UNICODE is only valid for a text file
700 - internal error

Remarks

$SF_* , $SFF_* constants are defined in RichEditConstants.au3
If text is selected, writes only the selection, else writes all text in the control.

Call _GUICtrlRichEdit_IsModified() to determine whether the text has changed.

Related

_GUICtrlRichEdit_SetLimitOnText, _GUICtrlRichEdit_StreamFromVar, _GUICtrlRichEdit_StreamToFile

See Also

Search EM_STREAMIN in MSDN Library.

Example

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0, $idLblMsg, $hRichEdit, $s
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($hRichEdit, "First paragraph")
    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; needed unless script crashes
                ; GUIDelete()   ; is OK too
                Exit
            Case $iMsg = $idBtnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        $s = _GUICtrlRichEdit_StreamToVar($hRichEdit)
                        GUICtrlSetData($idLblMsg, "Streamed to variable")
                    Case 2
                        _GUICtrlRichEdit_SetText($hRichEdit, "")
                        _GUICtrlRichEdit_StreamFromVar($hRichEdit, $s)
                        GUICtrlSetData($idLblMsg, "Streamed from variable")
                    Case 3
                        _GUICtrlRichEdit_SetSel($hRichEdit, 2, 6)
                        _GUICtrlRichEdit_StreamFromVar($hRichEdit, $s)
                        GUICtrlSetData($idLblMsg, "Replaced selection: an intentional mess!")
                        GUICtrlSetState($idBtnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Example