Function Reference


_GUICtrlStatusBar_IsSimple

Checks a status bar control to determine if it is in simple mode

#include <GuiStatusBar.au3>
_GUICtrlStatusBar_IsSimple ( $hWnd )

Parameters

$hWnd Handle to the control

Return Value

True: the status bar is in simple mode.
False: the status bar is not in simple mode.

Related

_GUICtrlStatusBar_SetSimple

Example

#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hStatus
    Local $aParts[3] = [75, 150, -1]

    ; Create GUI
    $hGUI = GUICreate("StatusBar IsSimple", 400, 300)

    $hStatus = _GUICtrlStatusBar_Create($hGUI)
    _GUICtrlStatusBar_SetParts($hStatus, $aParts)

    ; Create memo control
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Get/Set simple format
    MemoWrite("Simple mode on .: " & _GUICtrlStatusBar_IsSimple($hStatus))
    Sleep(1000)
    _GUICtrlStatusBar_SetSimple($hStatus, True)
    MemoWrite("Simple mode on .: " & _GUICtrlStatusBar_IsSimple($hStatus))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Write message to memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite