Function Reference


_GUICtrlStatusBar_SetSimple

Specifies whether a status window displays simple text or displays all window parts

#include <GuiStatusBar.au3>
_GUICtrlStatusBar_SetSimple ( $hWnd [, $bSimple = True] )

Parameters

$hWnd Handle to the control
$bSimple [optional] Sets the display of the windows
    True - The window displays simple text
    False - The window displays multiple parts

Return Value

None.

Related

_GUICtrlStatusBar_IsSimple

Example

#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hStatus
    Local $aParts[3] = [75, 150, -1]

    ; Create GUI
    $hGUI = GUICreate("StatusBar Set Simple", 400, 300)

    $hStatus = _GUICtrlStatusBar_Create($hGUI)
    _GUICtrlStatusBar_SetParts($hStatus, $aParts)

    ; Create memo control
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Get/Set simple format
    MemoWrite("Simple mode on .: " & _GUICtrlStatusBar_IsSimple($hStatus))
    Sleep(1000)
    _GUICtrlStatusBar_SetSimple($hStatus, True)
    MemoWrite("Simple mode on .: " & _GUICtrlStatusBar_IsSimple($hStatus))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Write message to memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite