Function Reference


_GUICtrlTab_DeselectAll

Resets tabs, clearing any that were set to the pressed state

#include <GuiTab.au3>
_GUICtrlTab_DeselectAll ( $hWnd [, $bExclude = True] )

Parameters

$hWnd Control ID/Handle to the control
$bExclude [optional] Exclusion flag:
    True - All tabs except for the one currently selected will be reset
    False - All tab items will be reset

Return Value

None.

Remarks

This only works if $TCS_BUTTONS style flag has been set.

Related

_GUICtrlTab_SetCurSel

Example

#include <GUIConstantsEx.au3>
#include <GuiTab.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idTab

    ; Create GUI
    GUICreate("Tab Control Deselect All", 400, 300)
    $idTab = GUICtrlCreateTab(2, 2, 396, 296, $TCS_BUTTONS)
    GUISetState(@SW_SHOW)

    ; Add tabs
    _GUICtrlTab_InsertItem($idTab, 0, "Tab 1")
    _GUICtrlTab_InsertItem($idTab, 1, "Tab 2")
    _GUICtrlTab_InsertItem($idTab, 2, "Tab 3")

    ; Select 2nd Tab Item
    _GUICtrlTab_SetCurSel($idTab, 1)

    ; Reset tab selection
    MsgBox($MB_SYSTEMMODAL, "Information", "Resetting tab selection")
    _GUICtrlTab_DeselectAll($idTab, False)

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example