Function Reference


_GUICtrlTab_SetCurSel

Selects a tab

#include <GuiTab.au3>
_GUICtrlTab_SetCurSel ( $hWnd, $iIndex )

Parameters

$hWnd Control ID/Handle to the control
$iIndex 0-based item index

Return Value

Success: the index of the previously selected tab.
Failure: -1.

Remarks

A tab control does not send a $TCN_SELCHANGING or $TCN_SELCHANGE notification message when a tab is selected using this function.

Related

_GUICtrlTab_DeselectAll, _GUICtrlTab_GetCurSel, _GUICtrlTab_HighlightItem

Example

#include <GUIConstantsEx.au3>
#include <GuiTab.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idTab

    ; Create GUI
    GUICreate("Tab Control Set Current Selected", 400, 300)
    $idTab = GUICtrlCreateTab(2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Add tabs
    _GUICtrlTab_InsertItem($idTab, 0, "Tab 1")
    _GUICtrlTab_InsertItem($idTab, 1, "Tab 2")
    _GUICtrlTab_InsertItem($idTab, 2, "Tab 3")

    ; Get/Set current selection
    _GUICtrlTab_SetCurSel($idTab, 1)
    MsgBox($MB_SYSTEMMODAL, "Information", "Current Selection: " & _GUICtrlTab_GetCurSel($idTab))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example