Function Reference


_GUICtrlTab_GetDisplayRectEx

Retrieves the display rectangle of the client area

#include <GuiTab.au3>
_GUICtrlTab_GetDisplayRectEx ( $hWnd )

Parameters

$hWnd Handle to the control

Return Value

Returns a $tagRECT structure that receives the rectangle of the tab, in viewport coordinates.

Remarks

Use this function to obtain the coordinates, in pixels, of the portion of the tab control that represents the contents of the tab pages.
The appearance of this portion of the tab control does not change when different tabs are selected.

Related

$tagRECT, _GUICtrlTab_GetDisplayRect

Example

#include <GUIConstantsEx.au3>
#include <GuiTab.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $tRECT, $sRect, $idTab

    ; Create GUI
    GUICreate("Tab Control Get Display RectEx", 400, 300)
    $idTab = GUICtrlCreateTab(2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Add tabs
    _GUICtrlTab_InsertItem($idTab, 0, "Tab 1")
    _GUICtrlTab_InsertItem($idTab, 1, "Tab 2")
    _GUICtrlTab_InsertItem($idTab, 2, "Tab 3")

    ; Get display rectangle
    $tRECT = _GUICtrlTab_GetDisplayRectEx(GUICtrlGetHandle($idTab))
    $sRect = StringFormat("[%d, %d, %d, %d]", DllStructGetData($tRECT, "Left"), _
            DllStructGetData($tRECT, "Top"), _
            DllStructGetData($tRECT, "Right"), _
            DllStructGetData($tRECT, "Bottom"))
    MsgBox($MB_SYSTEMMODAL, "Information", "Display rectangle: " & $sRect)

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example