Function Reference


_GUICtrlTab_GetItemRect

Retrieves the bounding rectangle for a tab

#include <GuiTab.au3>
_GUICtrlTab_GetItemRect ( $hWnd, $iIndex )

Parameters

$hWnd Control ID/Handle to the control
$iIndex 0-based item index

Return Value

Returns an array with the following format:
[0] = X coordinate of the upper left corner of the rectangle
[1] = Y coordinate of the upper left corner of the rectangle
[2] = X coordinate of the lower right corner of the rectangle
[3] = Y coordinate of the lower right corner of the rectangle

Related

_GUICtrlTab_GetItemRectEx

Example

#include <GUIConstantsEx.au3>
#include <GuiTab.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $aRect, $sRect, $idTab

    ; Create GUI
    GUICreate("Tab Control Get Item Rect", 400, 300)
    $idTab = GUICtrlCreateTab(2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Add tabs
    _GUICtrlTab_InsertItem($idTab, 0, "Tab 1")
    _GUICtrlTab_InsertItem($idTab, 1, "Tab 2")
    _GUICtrlTab_InsertItem($idTab, 2, "Tab 3")

    ; Get tab 0 rectangle
    $aRect = _GUICtrlTab_GetItemRect($idTab, 0)
    $sRect = StringFormat("[%d, %d, %d, %d]", $aRect[0], $aRect[1], $aRect[2], $aRect[3])
    MsgBox($MB_SYSTEMMODAL, "Information", "Tab 0 rectangle: " & $sRect)

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example