Function Reference

_GUICtrlToolbar_LoadImages

Loads system defined button images into a toolbar control's image list

#include <GuiToolbar.au3>
_GUICtrlToolbar_LoadImages ( $hWnd, $iBitMapID )

Parameters

$hWnd Handle to the control
$iBitMapID Identifier of a system-defined button image list. Can be set to one of the following values:
    $IDB_HIST_LARGE_COLOR
    $IDB_HIST_SMALL_COLOR
    $IDB_STD_LARGE_COLOR
    $IDB_STD_SMALL_COLOR
    $IDB_VIEW_LARGE_COLOR
    $IDB_VIEW_SMALL_COLOR
    $IDB_HIST_NORMAL
    $IDB_HIST_HOT
    $IDB_HIST_DISABLED
    $IDB_HIST_PRESSED

Return Value

Success: the count of images in the image list, not including the ones just added.
Failure: 0.

Example

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>

Example()

Func Example()
    Local $hGUI, $hToolbar, $aStrings[4]
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idHelp

    ; Create GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    GUISetState(@SW_SHOW)

    ; Add standard system bitmaps
    _GUICtrlToolbar_SetBitmapSize($hToolbar, 24, 24)
    _GUICtrlToolbar_LoadImages($hToolbar, $IDB_STD_LARGE_COLOR)

    ; Add strings
    $aStrings[0] = _GUICtrlToolbar_AddString($hToolbar, "&New Button")
    $aStrings[1] = _GUICtrlToolbar_AddString($hToolbar, "&Open Button")
    $aStrings[2] = _GUICtrlToolbar_AddString($hToolbar, "&Save Button")
    $aStrings[3] = _GUICtrlToolbar_AddString($hToolbar, "&Help Button")

    ; Add buttons
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW, $aStrings[0])
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN, $aStrings[1])
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE, $aStrings[2])
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idHelp, $STD_HELP, $aStrings[3])

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example