Function Reference


_GUICtrlTreeView_DisplayRect

Returns the bounding rectangle for a tree item

#include <GuiTreeView.au3>
_GUICtrlTreeView_DisplayRect ( $hWnd, $hItem [, $bTextOnly = False] )

Parameters

$hWnd Control ID/Handle to the control
$hItem Handle to the item whose rectangle will be returned
$bTextOnly [optional] If the True, the bounding rectangle includes only the text of the item.
Otherwise, it includes the entire line that the item occupies.

Return Value

Success: an array with the following format:
    $aRect[0] - X coordinate of the upper left corner of the rectangle
    $aRect[1] - Y coordinate of the upper left corner of the rectangle
    $aRect[2] - X coordinate of the lower right corner of the rectangle
    $aRect[3] - Y coordinate of the lower right corner of the rectangle
Failure: sets the @error flag to non-zero.

Related

_GUICtrlTreeView_DisplayRectEx

Example

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $ahItem[6], $hImage, $aRect, $idTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Display Rect", 400, 300)

    $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 146)
    _GUICtrlTreeView_SetNormalImageList($idTreeView, $hImage)

    For $x = 0 To _GUIImageList_GetImageCount($hImage) - 1
        $ahItem[$x] = _GUICtrlTreeView_Add($idTreeView, 0, StringFormat("[%02d] New Item", $x + 1), $x, $x)
    Next
    $aRect = _GUICtrlTreeView_DisplayRect($idTreeView, $ahItem[2])
    MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Item 2 Rectangle : [%d, %d, %d, %d]", $aRect[0], $aRect[1], $aRect[2], $aRect[3]))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example