Function Reference


_GUICtrlTreeView_Expand

Expands or collapses the list of child items associated with the specified parent item, if any

#include <GuiTreeView.au3>
_GUICtrlTreeView_Expand ( $hWnd [, $hItem = Null [, $bExpand = True]] )

Parameters

$hWnd Control ID/Handle to the control
$hItem [optional] Handle to the item
$bExpand [optional] Expand or Collapse, use the following values:
    True - Expand items
    False - Collapse items

Return Value

None.

Related

_GUICtrlTreeView_ExpandedOnce, _GUICtrlTreeView_GetExpanded

Example

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
        GUICreate("TreeView Expand (v" & @AutoItVersion & ")", 400, 300)

        Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
        Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
        GUISetState(@SW_SHOW)

        ; Set ANSI format
;~     _GUICtrlTreeView_SetUnicodeFormat($idTreeView, False)

        _GUICtrlTreeView_BeginUpdate($idTreeView)
        Local $aidItem[5]
        For $x = 0 To 4
                $aidItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $idTreeView)
                For $y = 0 To 2
                        GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $y), $aidItem[$x])
                Next
        Next
        _GUICtrlTreeView_EndUpdate($idTreeView)

        MsgBox($MB_SYSTEMMODAL, "Information", "Expand All")
        _GUICtrlTreeView_Expand($idTreeView)

        MsgBox($MB_SYSTEMMODAL, "Information", "Collapse All")
        _GUICtrlTreeView_Expand($idTreeView, 0, False)

        MsgBox($MB_SYSTEMMODAL, "Information", "Expand item 1")
        _GUICtrlTreeView_Expand($idTreeView, $aidItem[1])

        MsgBox($MB_SYSTEMMODAL, "Information", "Collapse item 1")
        _GUICtrlTreeView_Expand($idTreeView, $aidItem[1], False)

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
EndFunc   ;==>Example