Function Reference


_GUICtrlTreeView_GetFirstChild

Retrieves the first child item of the specified item

#include <GuiTreeView.au3>
_GUICtrlTreeView_GetFirstChild ( $hWnd, $hItem )

Parameters

$hWnd Control ID/Handle to the control
$hItem Handle to the item

Return Value

Success: the handle of the first child item.
Failure: 0.

Related

_GUICtrlTreeView_GetLastChild, _GUICtrlTreeView_GetNextChild, _GUICtrlTreeView_GetPrevChild

Example

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $aidItem[6], $hRandomItem, $idTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Get First Child", 400, 300)

    $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    For $x = 0 To UBound($aidItem) - 1
        $aidItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $idTreeView)
        For $y = 0 To 2
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $y), $aidItem[$x])
        Next
    Next
    _GUICtrlTreeView_EndUpdate($idTreeView)

    $hRandomItem = Random(0, UBound($aidItem) - 1, 1)
    MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Item %d handle of the first child? %s", $hRandomItem, _GUICtrlTreeView_GetFirstChild($idTreeView, $aidItem[$hRandomItem])))
    _GUICtrlTreeView_SelectItem($idTreeView, _GUICtrlTreeView_GetFirstChild($idTreeView, $aidItem[$hRandomItem]))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example