Function Reference


_GUICtrlTreeView_SetFocused

Sets whether the item appears to have focus

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetFocused ( $hWnd, $hItem [, $bFlag = True] )

Parameters

$hWnd Control ID/Handle to the control
$hItem Handle to the item
$bFlag [optional] Flag setting:
    True - Item appears to have focus
    False - Item does not

Return Value

Success: True.
Failure: False.

Related

_GUICtrlTreeView_GetFocused

Example

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
        GUICreate("TreeView Get/Set Focused (v" & @AutoItVersion & ")", 400, 300)

        Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
        Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
        GUISetState(@SW_SHOW)

        _GUICtrlTreeView_BeginUpdate($idTreeView)
        Local $aidItem[6]
        For $x = 0 To UBound($aidItem) - 1
                $aidItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x + 1), $idTreeView)
        Next
        _GUICtrlTreeView_EndUpdate($idTreeView)

        Local $hRandomItem = Random(0, UBound($aidItem) - 1, 1)
        MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Item %d Focused? %s", $hRandomItem, _GUICtrlTreeView_GetFocused($idTreeView, $aidItem[$hRandomItem])))
        _GUICtrlTreeView_SetFocused($idTreeView, $aidItem[$hRandomItem])
        MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Item %d Focused? %s", $hRandomItem, _GUICtrlTreeView_GetFocused($idTreeView, $aidItem[$hRandomItem])))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
EndFunc   ;==>Example