Function Reference


_GUICtrlTreeView_SetInsertMarkColor

Sets the color used to draw the insertion mark

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetInsertMarkColor ( $hWnd, $iColor )

Parameters

$hWnd Control ID/Handle to the control
$iColor Insertion mark color

Return Value

Returns the Previous insertion mark color.

Related

_GUICtrlTreeView_GetInsertMarkColor

Example

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $ahItem[6], $hImage, $iRand, $idTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Set Insert Mark Color", 400, 300)

    $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 146)
    _GUICtrlTreeView_SetNormalImageList($idTreeView, $hImage)

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    For $x = 0 To _GUIImageList_GetImageCount($hImage) - 1
        $ahItem[$x] = _GUICtrlTreeView_Add($idTreeView, 0, StringFormat("[%02d] New Item", $x + 1), $x, $x)
    Next
    _GUICtrlTreeView_EndUpdate($idTreeView)

    MsgBox($MB_SYSTEMMODAL, "Information", "Insert Mark Color: " & _GUICtrlTreeView_GetInsertMarkColor($idTreeView))

    _GUICtrlTreeView_SetInsertMarkColor($idTreeView, $COLOR_MONEYGREEN)

    $iRand = Random(0, 5, 1)
    _GUICtrlTreeView_SetInsertMark($idTreeView, $ahItem[$iRand])

    MsgBox($MB_SYSTEMMODAL, "Information", "Insert Mark Color: " & _GUICtrlTreeView_GetInsertMarkColor($idTreeView))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example