Function Reference


_GUICtrlTreeView_SetItemHeight

Sets the height of an individual item

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetItemHeight ( $hWnd, $hItem, $iIntegral )

Parameters

$hWnd Control ID/Handle to the control
$hItem Handle to the item
$iIntegral Height of the item. This height is in increments of the standard item height. By default, each
item gets one increment of item height. Setting this field to 2 will give the item twice the standard height;
setting this field to 3 will give the item three times the standard height; and so on. The control does not
draw in this extra area.

Return Value

Success: True.
Failure: False.

Example

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $aidItem[6], $idTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Set Item Height", 400, 300)

    $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    For $x = 0 To UBound($aidItem) - 1
        $aidItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x + 1), $idTreeView)
    Next
    _GUICtrlTreeView_EndUpdate($idTreeView)

    _GUICtrlTreeView_SetItemHeight($idTreeView, $aidItem[2], 2)

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example