Function Reference


_GUIToolTip_GetText

Retrieves the text of a tool

#include <GuiToolTip.au3>
_GUIToolTip_GetText ( $hWnd, $hTool, $iID )

Parameters

$hWnd Handle to the ToolTip control (returned by _GUIToolTip_Create.)
$hTool Handle to the window that contains the tool
$iID Identifier of the tool, or Window handle of the control the tool is assigned to

Return Value

Returns the text of the specified tool. On non-AutoIt created ToolTips it only retrieves the first 42 characters of the text of the specified tool.

Related

_GUIToolTip_UpdateTipText

Example

Example 1

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGUI = GUICreate(StringTrimRight(@ScriptName, StringLen(".exe")), 350, 200)

    Local $idButton = GUICtrlCreateButton("Button", 30, 32, 130, 28)
    Local $hButton = GUICtrlGetHandle($idButton)

    Local $hToolTip = _GUIToolTip_Create($hGUI)

    _GUIToolTip_AddTool($hToolTip, 0, "This is the ToolTip text", $hButton)

    GUISetState(@SW_SHOW)
    ; Retrieve the text of the tool
    MsgBox($MB_SYSTEMMODAL, 'Message', _GUIToolTip_GetText($hToolTip, 0, $hButton))

    While 1
        If GUIGetMsg() = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
    ; Destroy the tooltip control
    _GUIToolTip_Destroy($hToolTip)
    GUIDelete($hGUI)
EndFunc   ;==>Example

Example 2

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>
#include <MsgBoxConstants.au3>

Global $g_iPID

; Hover over one of the characters in the Charmap app to get a tooltip to display, then press 'g' to
; retrieve its text information.
HotKeySet('g', "_Read_Tip")

Example()

Func Example()
    ; Run character map program
    $g_iPID = Run("charmap.exe")
    ; Wait for it to become the active window
    WinWaitActive("Character Map", "", 10)
    While ProcessExists($g_iPID)
        Sleep(100)
    WEnd
EndFunc   ;==>Example

Func _Read_Tip()
    ; Get list of tooltips
    Local $aTipList = WinList("[CLASS:tooltips_class32]")
    Local $aRet
    ; See which belong to your app
    For $i = 1 To $aTipList[0][0]
        If WinGetProcess($aTipList[$i][1]) = $g_iPID Then
            ; See which one is active
            $aRet = _GUIToolTip_GetCurrentTool($aTipList[$i][1])
            ; If one is active then display it
            If $aRet[8] <> "" Then MsgBox(0, "Visible Tip", $aRet[8])
        EndIf
    Next
EndFunc   ;==>_Read_Tip