Holding Key Down...

[eco]

doesn't work for me :/, when i launch script it only writes 1 a letter

Send("{a down}")

Sleep(2000)

Send("{a up}")

[Simucal]

doesn't work for me :/, when i launch script it only writes 1 a letter

Send("{a down}")

Sleep(2000)

Send("{a up}")

EDIT: Listen to herewasplato.

Edited May 1, 2006 by Simucal

[herewasplato]

Look up AutoItSetOption in the help file.

SendKeyDownDelay

Alters the length of time a key is held down before released during a keystroke. For applications that take a while to register keypresses (and many games) you may need to raise this value from the default.

Time in milliseconds to pause (default=1).

[eco]

how do i change that delay in script, what to write and where, sorry but this is totally new to me

tried this in beginning of script, but didn't help

Opt("SendKeyDownDelay", 20)

Edited May 1, 2006 by eco

[cdkid]

Opt("OPTIONNAME","VALUE")

at the top of your script

~cdkid

PS: Lookup AutoItSetOption in the helpfile

[Don N]

Put this line at the top of your script

Opt("SendKeyDelay", 5)       ;delays for 5 milliseconds

or

AutoItSetOption( "SendKeyDelay", 5 )   ;delays for 5 milliseconds

[SmOke_N]

Or you could just make a UDF to do it:

_SendDuration('a', 2000)
;Could be like: _SendDuration('a', 2000, 50, 50) if you wanted

Func _SendDuration($v_Send, $i_Duration, $i_SendDownDelay = 1, $i_SendKeyDelay = 1)
    $OptSendDownDelay = Opt('SendKeyDownDelay', $i_SendDownDelay)
    $OptSendKeyDelay = Opt('SendKeyDelay', $i_SendKeyDelay)
    Local $SendTimer = TimerInit()
    Do
        Send($v_Send)
    Until TimerDiff($SendTimer) >= $i_Duration
    Opt('SendKeyDownDelay', $OptSendDownDelay)
    Opt('SendKeyDelay', $OptSendKeyDelay)
EndFunc

Edit:

Added parameters for sendkeydelay and sendkeydowndelay.

Edited May 1, 2006 by SmOke_N

[eco]

it doesnt work for some reason , this is my code

HotKeySet("{F11}", "start")
HotkeySet("{HOME}","end")
Opt("SendKeyDelay", 5)

While 1 
sleep ("100") 
WEnd 

Func start()

Send("{a down}")
Sleep(5000)
Send("{a up}") 

EndFunc

Func end()
Exit 0
EndFunc

[Don N]

Have u tried AutoItSetOption() or increasing the delay to a # > 5. Also try the example posted by smoke_n. One of those solutions should work.

[eco]

yes, i tried also AutoItSetOption() and delay to a # > 5

i would try SmOke_N's solution, if i understood something from it

[cdkid]

What this does

Func _SendDuration($v_Send, $i_Duration, $i_SendDownDelay = 1, $i_SendKeyDelay = 1)
    $OptSendDownDelay = Opt('SendKeyDownDelay', $i_SendDownDelay)
    $OptSendKeyDelay = Opt('SendKeyDelay', $i_SendKeyDelay)
    Local $SendTimer = TimerInit()
    Do
        Send($v_Send)
    Until TimerDiff($SendTimer) >= $i_Duration
    Opt('SendKeyDownDelay', $OptSendDownDelay)
    Opt('SendKeyDelay', $OptSendKeyDelay)
EndFunc

Is start a timer, and send the specified key until that timer = $i_Duration in miliseconds

The two optional parameters are for setting the SendKeyDelay & SendKeyDownDelay while it does that.

--Hope this helps

~cdkid

[eco]

cdkid, i tried to put it in beginning of script, but no effect either

strange that MouseDown("left") works, but not with keyboard

but does it work to you?

HotKeySet("{F11}", "start")

HotkeySet("{HOME}","end")

Opt("SendKeyDelay", 5)

While 1

sleep ("100")

WEnd

Func start()

Send("{a down}")

Sleep(5000)

Send("{a up}")

EndFunc

Func end()

Exit 0

EndFunc

[SmOke_N]

cdkid, i tried to put it in beginning of script, but no effect either

strange that MouseDown("left") works, but not with keyboard

but does it work to you?

HotKeySet("{F11}", "start")

HotkeySet("{HOME}","end")

Opt("SendKeyDelay", 5)

While 1

sleep ("100")

WEnd

Func start()

Send("{a down}")

Sleep(5000)

Send("{a up}")

EndFunc

Func end()

Exit 0

EndFunc

HotKeySet("{F11}", "start")
HotkeySet("{HOME}","end")

While 1
    Sleep(100)
WEnd

Func start()
    _SendDuration('a', 5000, 5, 5)
EndFunc

Func end()
    Exit 0
EndFunc

Func _SendDuration($v_Send, $i_Duration, $i_SendDownDelay = 1, $i_SendKeyDelay = 1)
    $OptSendDownDelay = Opt('SendKeyDownDelay', $i_SendDownDelay)
    $OptSendKeyDelay = Opt('SendKeyDelay', $i_SendKeyDelay)
    Local $SendTimer = TimerInit()
    Do
        Send($v_Send)
    Until TimerDiff($SendTimer) >= $i_Duration
    Opt('SendKeyDownDelay', $OptSendDownDelay)
    Opt('SendKeyDelay', $OptSendKeyDelay)
EndFunc

[eco]

it is more complicated than i thought, but it works, thanks, also thx to others

[SmOke_N]

Nothing complicated really, I'll try to break it down for you:

Func _SendDuration($v_Send, $i_Duration, $i_SendDownDelay = 1, $i_SendKeyDelay = 1)

$v_Send = The character(s) you want to send

$i_Duration = How long you want to send the character(s)

$i_SendDownDelay = 1 = Optional Parameter -- If you need it longer than one for the Opt('SendKeyDownDleay') then you would use it like i did (5 or whatever) else you would not use it at all example _SendDuration('a', 5000)

$i_SendKeyDelay = 1 = Same as above

$OptSendDownDelay = Opt('SendKeyDownDelay', $i_SendDownDelay)
    $OptSendKeyDelay = Opt('SendKeyDelay', $i_SendKeyDelay)

Storing the original settings for these Opt(s) so that you don't have to keep doing it throughout your script

Local $SendTimer = TimerInit()

Local (keeping the variable specific for this function)

TimerInit() ; Start the timer for the $i_Duration settings

Do
        Send($v_Send)
    Until TimerDiff($SendTimer) >= $i_Duration

Do/Until is a loop, so you will continue to send your character(s) until the desired time (TimerDiff($SendTime)) has expired.

Opt('SendKeyDownDelay', $OptSendDownDelay)
    Opt('SendKeyDelay', $OptSendKeyDelay)

Re-storing back to what these Opt(s) were originally before you started the function.

Hope that helps... It could even use another parameter for sending keys raw.

[greenmachine]

If you'll notice, the helpfile says this:

To hold a key down (generally only useful for games)

Send("{a down}") ;Holds the A key down

Send("{a up}") ;Releases the A key

The reason it is "generally only useful for games" is because it is designed to not send more than one key. Games respond to keys being held down the same regardless of settings on the computer, but keys being sent are subject to key delays (how long before repeating, what repeat rate...). Jon discussed this before, but I couldn't find the thread. Anyway, he said that it was made this way on purpose.

The function provided above, while nice and potentially useful, is the same as doing Send ("{a XX}"), where XX is simply the number of keys sent during the time period. That could be calculated with some quick math beforehand, and then the function wouldn't be needed. Just so you know....