Access Database Connection

[WDoherty]

Hi,

I am a newbie and have tried connecting to a Access database on my desktop. I have used the below with no luck, I get the following error:

Line 24: (File "C:\Documents and Settings etc.

$adoRs.Open ($query, $adoCon)

$adoRs.Open ($query, $adoCon)^ERROR

Error: The requested acction with this object has failed.

$dbname = "C:\Documents and Settings\DOHERTYW\Desktop\NHS Status.mdb"

$tblname = "TBL_LowerCase"

$query = "SELECT * FROM " & $tblname & " WHERE DistrictNumber = 1"

Local $title

$adoCon = ObjCreate("ADODB.Connection")

$adoCon.Open("Driver={Microsoft Access Driver (*.mdb)}; DBQ=" & $dbname) ;Use this line if using MS Access 2003 and lower

;$adoCon.Open ("Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & $dbname) ;Use this line if using MS Access 2007 and using the .accdb file extension

$adoRs = ObjCreate ("ADODB.Recordset")

$adoRs.CursorType = 1

$adoRs.LockType = 3

$adoRs.Open ($query, $adoCon)

$title = $adoRs.Fields("DistrictNumber").value ;Retrieve value by field name

;$title = $adoRs.Fields(2).value ;Retrieve value by column number

$adoCon.Close

MsgBox(0,"testing",$title)

[PsaltyDS]

I don't see you testing if .Open was successful on your connection before moving on. Also, a COM Error handler should be included anytime you use COM objects in AutoIt:

$oMyError = ObjEvent("AutoIt.Error", "MyErrFunc") ; Install a custom error handler

$adStateClosed = 0x0 ; The object is closed
$adStateOpen = 0x1 ; The object is open
$adStateConnecting = 0x2 ; The object is connecting
$adStateExecuting = 0x4 ; The object is executing a command
$adStateFetching = 0x8 ; The rows of the object are being retrieved

; ...

$adoCon.Open("Driver={Microsoft Access Driver (*.mdb)}; DBQ=" & $dbname)
$iADOState = $adoCon.State
If $iADOState = $adStateOpen Then
    MsgBox(64, "Success", "Connection object is open.")
Else
    MsgBox(16, "Error", "Connection is not open; $adoCon.State = " & $iADOState)
EndIf

; ...

; This is my custom error handler
Func MyErrFunc()
    $HexNumber = Hex($oMyError.number, 8)
    MsgBox(16, "COM Error", "We intercepted a COM Error!" & @CRLF & _
            "Number is: " & $HexNumber & @CRLF & _
            "Windescription is: " & $oMyError.windescription)
EndFunc   ;==>MyErrFunc