Alert when Control loses FOCUS

[smahdi83]

Hi,

How can I check if a certain textbox lost focus? Please this is really important and I have no clue on how to do that?

Thanks,

Edited September 26, 2007 by smahdi83

[smahdi83]

Is there any way in Autoit to trigger an event as soon as a textbox loses focus? I can't seem to find anything to help me do that.

[martin]

Hi,

How can I check if a certain textbox lost focus? Please this is really important and I have no clue on how to do that?

Thanks,

You could do it like this (assuming a textbox is an edit)-

#INCLUDE <GUICONSTANTS.AU3>
#include <constants.au3>
Global Const $WM_COMMAND = 0x0111
Global Const $EN_KILLFOCUS = 0x0200

$w1 = GUICreate('edit lost focus')

$edit1 = GUICtrlCreateEdit("some text", 20, 20, 120, 80)
$edit2 = GUICtrlCreateEdit("some text", 20, 120, 120, 80)
GUIRegisterMsg($WM_COMMAND, "MY_WM_COMMAND")
GUISetState()

While GUIGetMsg() <> -3
WEnd


Func MY_WM_COMMAND($hWnd, $msg, $wParam, $lParam)
    Local $nNotifyCode = BitShift($wParam, 16)
    Local $nID = BitAND($wParam, 0xFFFF)
    Local $hCtrl = $lParam

    Switch $nID
        Case $edit1
            Switch $nNotifyCode
                Case $EN_KILLFOCUS
                    MsgBox(0, 'EDIT LOST FOCUS', 'from Edit1')
            EndSwitch
    EndSwitch

    Return $GUI_RUNDEFMSG
EndFunc ;==>MY_WM_COMMAND

It's actually easy to find the notifications and messages for a control.

Have a look here.]

EDIT: Added link to msdn

Edited September 26, 2007 by martin