DllStructCreate: Struct of a Struct Possible?

[Locodarwin]

I'm automating the Canon SDK for the Canon PowerShot A640 series digital camera, and I've come up against a situation that I'd like to find a clean solution for.

Is it possible to create a DLLStruct in AutoIt that is basically an array of another struct?

The export function PR_GetDllsVersion() retrieves the version number of the DLL modules used in the SDK. Its syntax is:

PR_GetDllsVersion(
            prUInt32*           pBufferSize,
            prDllsVerInfo*      pDllVersion
                  );

In C, the structs associated with this function look like this:

typedef struct{
    prWChar ModuleName[512];                /* Module name (512 characters) */
    prWChar Version[32];                    /* Version (32 characters) */
}prVerInfo;

typedef struct{
    prUInt32  Entry;                        /* Number of modules included in this structure */
    prVerInfo VerInfo[prANY];                 /* Array of file version number information of PS-ReC SDK modules */
}prDllsVerInfo;

So according to this, prDllsVerInfo contains an array of the prVerInfo data type, which in turn is a user defined struct.

I presume I can just pass a simple char array that is the total size of prVerInfo and parse the data out myself later, but I'm looking for a cleaner way to do it that logically follows how it would be done in C.

Any suggestions?

Thanks in advance,

-S

[Locodarwin]

Bump.

[Siao]

;#1
;creating
$iCount = 5
$sVerInfo = "wchar[512];wchar[32];"
$sDllsVerInfo = "uint;"
For $i = 1 To $iCount
    $sDllsVerInfo &= $sVerInfo
Next
$sDllsVerInfo = StringTrimRight($sDllsVerInfo, 1)
$tDllsVerInfo = DllStructCreate($sDllsVerInfo)
DllStructSetData($tDllsVerInfo, 1, $iCount)
;reading back:
For $i = 1 To DllStructSetData($tDllsVerInfo, 1)
    ConsoleWrite('Module name: ' & DllStructGetData($tDllsVerInfo, $i * 2) & @CRLF)
    ConsoleWrite('Version: ' & DllStructGetData($tDllsVerInfo, $i * 2 + 1) & @CRLF)
Next

;#2
;creating
$iCount = 5
$iSizeVerInfo = (512+32)*2
$tDllsVerInfo = DllStructCreate('uint;byte[' & $iSizeVerInfo * $iCount & ']')
DllStructSetData($tDllsVerInfo, 1, $iCount)
;reading back:
For $i = 0 To DllStructSetData($tDllsVerInfo, 1) - 1
    $tVerInfo = DllStructCreate("wchar[512];wchar[32]", DllStructGetPtr($tDllsVerInfo, 2) + $iSizeVerInfo * $i)
    ConsoleWrite('Module name: ' & DllStructGetData($tVerInfo, 1) & @CRLF)
    ConsoleWrite('Version: ' & DllStructGetData($tVerInfo, 2) & @CRLF)
Next