how to delete a local group/account?

[netegg]

I've got how to list the groups/users in a machine through the forum? But I have no idea to delete the specific group/user.

Someone can help me?

Edited May 28, 2008 by netegg

[weaponx]

RunWait("net user username /DELETE")

[netegg]

RunWait("net user username /DELETE")

Can it do without using "net" command?

[weaponx]

Can it do without using "net" command?

Why?

[enaiman]

Maybe because he might not have administrative rights?

. . .

[Jos]

Here is a example how to Add/Rename/Delete a user and put it in a group:

expandcollapse popup

; Init objects
$oMyError = ObjEvent("AutoIt.Error","MyErrFunc"); Install a custom error handler 
$UserName = 'Fred'
$Password = 'Wilma123'
$strComputer = @ComputerName
;***********************
;Create UserID
$colAccounts = ObjGet("WinNT://" & $strComputer & "")
$objUser = $colAccounts.Create("user", $UserName)
$objUser.SetPassword ($Password)
$objUser.Put ("Fullname", "Test User")
$objUser.Put ("Description", "Test User description")
$objUser.Put ("PasswordExpired", 1) ;expire the password
$objUser.SetInfo
;***********************
;Add User to group 
$objGroup = ObjGet("WinNT://" & $strComputer & "/Administrators,group")
$objGroup.Add($objUser.ADsPath)
;***********************
; Rename User
$colAccounts = ObjGet("WinNT://" & $strComputer & "")
$objUser = $colAccounts.Create("user", $UserName)
$OldUser = "Fred"
$NewUser = "Fredrenamed"
$oUser = ObjGet("WinNT://" & @ComputerName & "/" & $OldUser & ",user")
$oComputer = ObjGet("WinNT://" & @ComputerName)
$oNewUser = $oComputer.MoveHere($oUser.ADsPath, $NewUser)
; Delete User
$colAccounts = ObjGet("WinNT://" & $strComputer & "")
$objUser = $colAccounts.Delete("user", $NewUser)


Func MyErrFunc() 
   $HexNumber=hex($oMyError.number,8) 
   Msgbox(0,"","We intercepted a COM Error !" & @CRLF & _
                "Number is: " & $HexNumber & @CRLF & _
                "Linenbr is: " & $oMyError.scriptline  & @CRLF & _
                "Description is: " & $oMyError.description  & @CRLF & _
                "Windescription is: " & $oMyError.windescription ) 

   SetError(1); something to check for when this function returns 
Endfunc