GDI+ and paint

[Andreik]

I want to create an area 400x400 like in Paint, when I click in this area to put black color (dot) at mouse x position and y position.

[monoceres]

Hi!

Here's a basic idea:

#include <GDIPlus.au3>
#include <misc.au3>
Opt("GUIOnEventMode",1)
Opt("MouseCoordMode",2)
$hwnd=GUICreate("Sample",400,400)
GUISetOnEvent(-3,"close")
GUISetState()

_GDIPlus_Startup()
$graphics=_GDIPlus_GraphicsCreateFromHWND($hwnd)
_GDIPlus_GraphicsClear($graphics,0xFFFFFFFF)
$brush=_GDIPlus_BrushCreateSolid(0xFF000000)

$dll=DllOpen("user32.dll")

Do
    If _IsPressed("01",$dll) Then
        _GDIPlus_GraphicsFillRect($graphics,MouseGetPos(0),MouseGetPos(1),2,2,$brush)
        Do
            Sleep(25)
        Until Not _IsPressed("01",$dll)
    EndIf
    Sleep(25)
Until False



Func close()
    _GDIPlus_BrushDispose($brush)
    _GDIPlus_GraphicsDispose($graphics)
    _GDIPlus_Shutdown()
    Exit
EndFunc

muttley

[Andreik]

Thanks monoceres, it`s perfect. If I want to switch colors (red, yellow, blue,pink,...) I should modify brush color?

$brush=_GDIPlus_BrushCreateSolid(0xFF000000)

[monoceres]

Thanks monoceres, it`s perfect. If I want to switch colors (red, yellow, blue,pink,...) I should modify brush color?

$brush=_GDIPlus_BrushCreateSolid(0xFF000000)

Yup muttley

[Andreik]

How can I do, if I don't release mouse left click, to continue drawing, like in paint.

[monoceres]

How can I do, if I don't release mouse left click, to continue drawing, like in paint.

Add this to the Do...Until loop inside the If statement:

$pos = MouseGetPos()
_GDIPlus_GraphicsFillRect($graphics, $pos[0], $pos[1], 2, 2, $brush)

You should also remove the sleep.

[Andreik]

Work fine. Thanks.

[monoceres]

I made a even better version, it now acts just like paint muttley

#include <GDIPlus.au3>
#include <misc.au3>
Opt("GUIOnEventMode", 1)
Opt("MouseCoordMode", 2)
$hwnd = GUICreate("Sample", 400, 400)
GUISetOnEvent(-3, "close")
GUISetState()

_GDIPlus_Startup()
$graphics = _GDIPlus_GraphicsCreateFromHWND($hwnd)
_GDIPlus_GraphicsClear($graphics, 0xFFFFFFFF)
$pen = _GDIPlus_PenCreate(0xFF00FF00)

$dll = DllOpen("user32.dll")

Do
    If _IsPressed("01", $dll) And WinActive("Sample") Then
        $oldpos=MouseGetPos()
        _GDIPlus_GraphicsDrawRect($graphics,$oldpos[0],$oldpos[1],1,1,$pen)
        Do
            $pos = MouseGetPos()
            _GDIPlus_GraphicsDrawLine($graphics,$oldpos[0],$oldpos[1],$pos[0],$pos[1],$pen)
            $oldpos=$pos
        Until Not _IsPressed("01", $dll)
    EndIf
    Sleep(25)
Until False



Func close()
    _GDIPlus_PenDispose($pen)
    _GDIPlus_GraphicsDispose($graphics)
    _GDIPlus_Shutdown()
    Exit
EndFunc  ;==>close

Edited July 8, 2008 by monoceres

[Andreik]

Nice script. It`s perfect. Thank you very much.

[Zedna]

You can use simpler SetPixel API.

There are examples on the forum for it.

[Andreik]

You can use simpler SetPixel API.

There are examples on the forum for it.

Just check, SetPixel is another way. Thanks!