Getting selected text in _GuiCtrlEdit

[torels]

Hi there

How do I get the selected text in a _GuiCtrlEdit ?

thaks in advance

[Minikori]

Hi there

How do I get the selected text in a _GuiCtrlEdit ?

thaks in advance

If you mean an edit control, then GUICtrlRead() will do it.

EDIT: Oh selected text, my bad.

Edited October 1, 2008 by Minikori

[PsaltyDS]

Hi there

How do I get the selected text in a _GuiCtrlEdit ?

thaks in advance >_<

You get the selection by start/stop character offsets with _GuiCtrlEdit_GetSel(). Then just use StringMid() to pick it out. Demo:

expandcollapse popup

#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>

Global $avSelection[2], $sText
Global $StatusBar, $hEdit, $hGUI
Global $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\AutoIt v3\AutoIt", "InstallDir") & _
        "\include\changelog.txt"
Global $aPartRightSide[3] = [190, 378, -1], $aSel

; Create GUI
$hGUI = GUICreate("Edit Get Sel", 400, 300)
$hEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
$StatusBar = _GUICtrlStatusBar_Create($hGUI, $aPartRightSide)
_GUICtrlStatusBar_SetIcon($StatusBar, 2, 97, "shell32.dll")
GUISetState()

; Set Margins
_GUICtrlEdit_SetMargins($hEdit, BitOR($EC_LEFTMARGIN, $EC_RIGHTMARGIN), 10, 10)

; Set Text
_GUICtrlEdit_SetText($hEdit, FileRead($sFile))

; Set Sel
_GUICtrlEdit_SetSel($hEdit, 15, 20)


; Loop until user exits
Do
; Get Sel
    $aSel = _GUICtrlEdit_GetSel($hEdit)
    If ($aSel[0] <> $avSelection[0]) Or ($aSel[1] <> $avSelection[1]) Then
        $avSelection = $aSel
        _GUICtrlStatusBar_SetText($StatusBar, "Start: " & $aSel[0])
        _GUICtrlStatusBar_SetText($StatusBar, "End: " & $aSel[1], 1)
    EndIf
Until GUIGetMsg() = $GUI_EVENT_CLOSE

$sText = StringMid(_GUICtrlEdit_GetText($hEdit), $avSelection[0], $avSelection[1] - $avSelection[0] + 1)
MsgBox(64, "Selection", $sText)
GUIDelete()

[torels]

Thanks PsaltyDS =D