GUICtrlSetOnEvent on dynamic menu items

[ACalcutt]

Hey guys,

I am trying to create a menu in my vistumbler program that lets the use choose the network adapter they want to use.

I am using this code to create menu items and save the button ID into an array

$Interfaces = GUICtrlCreateMenu("Interfaces")
$objWMIService = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2")
$colNIC = $objWMIService.ExecQuery("Select * from Win32_NetworkAdapter WHERE Netconnectionstatus = 2")
Dim $NetworkAdapters[1]
$menuid = GUICtrlCreateMenuItem("Default", $Interfaces)
_ArrayAdd($NetworkAdapters, $menuid)
GUICtrlSetOnEvent($menuid, '_InterfaceChanged')
For $object In $colNIC
    $menuid = GUICtrlCreateMenuItem($object.NetConnectionID, $Interfaces)
    _ArrayAdd($NetworkAdapters, $menuid)
    GUICtrlSetOnEvent($menuid, '_InterfaceChanged')
Next

The problem I am having is I have no idea how to tell what button was pressed.

I want to make it so when in interface is picked it will put a checkbox next to the interface and change a variable in my script.

Does anyone know how i can tell what button was clicked or do this a different way?

Edited October 15, 2008 by ACalcutt

[Monamo]

Hey guys,

I am trying to create a menu in my vistumbler program that lets the use choose the network adapter they want to use.

I am using this code to create menu items and save the button ID into an array

$Interfaces = GUICtrlCreateMenu("Interfaces")
$objWMIService = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2")
$colNIC = $objWMIService.ExecQuery("Select * from Win32_NetworkAdapter WHERE Netconnectionstatus = 2")
Dim $NetworkAdapters[1]
$menuid = GUICtrlCreateMenuItem("Default", $Interfaces)
_ArrayAdd($NetworkAdapters, $menuid)
GUICtrlSetOnEvent($menuid, '_InterfaceChanged')
For $object In $colNIC
    $menuid = GUICtrlCreateMenuItem($object.NetConnectionID, $Interfaces)
    _ArrayAdd($NetworkAdapters, $menuid)
    GUICtrlSetOnEvent($menuid, '_InterfaceChanged')
Next

The problem I am having is I have no idea how to tell what button was pressed.

I want to make it so when in interface is picked it will put a checkbox next to the interface and change a variable in my script.

Does anyone know how i can tell what button was clicked or do this a different way?

You could use the GUICtrlRead() function with the advanced parameter (without the advanced parameter, you'll just get the state of the menu item).

An example function to show the return based upon your posted code would be (AutoIt v3.2.10.0):

Func _InterfaceChanged()
    ConsoleWrite(GUICtrlRead(@GUI_CtrlId,1) &" was selected." &@CRLF)
EndFunc

[ACalcutt]

Thanks for your help. that should work

Func _InterfaceChanged()
    $menuid = @GUI_CtrlId
    For $uc = 1 To $NetworkAdapters[0]
        If $NetworkAdapters[$uc] = $menuid Then
            GUICtrlSetState($NetworkAdapters[$uc], $GUI_CHECKED)
        Else
            GUICtrlSetState($NetworkAdapters[$uc], $GUI_UNCHECKED)
        EndIf
    Next
    $DefaultApapter = GUICtrlRead(@GUI_CtrlId, 1)
    ConsoleWrite(@GUI_CtrlId & '-' & GUICtrlRead(@GUI_CtrlId, 1) & " was selected." & @CRLF)
EndFunc  ;==>_InterfaceChanged

-Andrew

Edited October 15, 2008 by ACalcutt