Would it be possible to read the TrayTip?

[Jumper4000]

I'm trying to read the text that appears in the System Tray Tip and do something based on what it shows. Is that possible?

Thanks

[PsaltyDS]

I'm trying to read the text that appears in the System Tray Tip and do something based on what it shows. Is that possible?

Thanks

This demo reads the text of all the tools present in the tooltip of the system try toolbar (requires current Beta):

expandcollapse popup

#Include <GuiToolBar.au3>
#Include <GuiToolTip.au3>

HotKeySet("{ESC}", "_Quit")

; Get handle to system tray
Global $hTrayWnd = WinGetHandle("[CLASS:Shell_TrayWnd]")
If @error Then 
    MsgBox(16, "Error", "Failed to get sytem tray window handle.")
    Exit
Else
    ConsoleWrite("Debug: $hTrayWnd = " & $hTrayWnd & @LF)
EndIf

; Get handle to sytem tray ToolBar
Global $hToolBar = ControlGetHandle($hTrayWnd, "", "[CLASS:ToolbarWindow32;INSTANCE:1]")
If @error Then 
    MsgBox(16, "Error", "Failed to get sytem tray toolbar handle.")
    Exit
Else
    ConsoleWrite("Debug: $hToolBar = " & $hToolBar & @LF)
EndIf

; Get ToolTip handle for ToolBar
Global $hToolTip = HWnd("0x" & Hex(_GUICtrlToolbar_GetToolTips($hToolBar), 8))
ConsoleWrite("Debug: $hToolTip = " & $hToolTip & @LF)

; Get count of tools in ToolTip
Global $iToolCount = _GUIToolTip_GetToolCount($hToolTip)
ConsoleWrite("Debug: $iToolCount = " & $iToolCount & @LF)

; List text of all the tools in the ToolTip
For $n = 0 To $iToolCount - 1
    $sToolText = _GUIToolTip_GetText($hToolTip, $hToolBar, $n)
    ConsoleWrite("Debug: Tool " & $n & ":  " & $sToolText & @LF)
Next


Func _Quit()
    Exit
EndFunc

I haven't had time to experiment with _GUIToolTip_GetCurrentTool() to see about detecting if a tool is active or not. But maybe this help move the ball.