IE doesnt work

[Joke758]

why? doesn't fill the form in the message

Func _hotmail($user, $subject, $message)
    $oIE = _IECreate ("http://hotmail.com", 0, 1)
    $o_form = _IEFormGetCollection ($oIE, 0)
    $o_name = _IEFormElementGetObjByName ($o_form, "login")
    $o_pass = _IEFormElementGetObjByName ($o_form, "passwd")
    
    _IEFormElementSetValue ($o_name, YOUREMAILHERE)
    _IEFormElementSetValue ($o_pass, YOURPASSHERE)
    
    $submit = _IEFormElementGetObjByName ($o_form, "SI" )
    _IEAction ( $submit, "click" )
    _IeLoadWait ( $oIE )
    
    $oIE = _IeNavigate ( $oIE, "http://by22fd.bay22.hotmail.msn.com/cgi-bin/compose?&curmbox=F000000001&a=07dbc459228078e3757682bc9a9f511a402e984638143dd6499fd5b04719737e" )
    $o_form2 = _IEFormGetCollection ($oIE, 0)
    
    $o_to = _IEFormElementGetObjByName ($o_form2, "to")
    $o_subject = _IEFormElementGetObjByName ($o_form2, "subject")
    $o_body = _IEFormElementGetObjByName ($o_form2, "body")
    
    _IEFormElementSetValue ($o_to, "grison4@hotmail.com")
    _IEFormElementSetValue ($o_subject, "hey")
    _IEFormElementSetValue ($o_body, "test")

EndFunc

why? and how can I submit?

[vim]

_IEFormElementSetValue ($o_name, YOUREMAILHERE)

_IEFormElementSetValue ($o_pass, YOURPASSHERE)

Is this really your Hotmail userID & Password?

[Joke758]

No, put your account and pass to try my function

It doesn't works... weird

[DaleHohm]

Just because you aren't using it correctly doesn't mean it doesn't work

There are 3 forms on that second page and you are getting a reference to the first one (index = 0). Try index = 2 instead.

Dale

[Joke758]

I waqs refering to my script because it doesn't work. Thanks alot!

[big_daddy]

It was your function that didn't work, not IE.au3.

expandcollapse popup

#include <IE.au3>

_Hotmail("your-email@hotmail.com", "yourpassword", "someone@somewhere.com", "Test Subject", "Test Message")

Func _Hotmail($s_Email, $s_Password, $s_To, $s_Subject, $s_Body)
    $o_IE = _IECreate("http://hotmail.com", 0, 1)
    $o_Form = _IEFormGetObjByName($o_IE, "f1")
    $o_Name = _IEFormElementGetObjByName($o_Form, "login")
    $o_Pass = _IEFormElementGetObjByName($o_Form, "passwd")

    _IEFormElementSetValue($o_Name, $s_Email)
    _IEFormElementSetValue($o_Pass, $s_Password)
    _IEFormSubmit($o_Form, 0)
    _IELoadWait($o_IE, 500)
    
    $o_Links = _IELinkGetCollection($o_IE)
    For $o_Link In $o_Links
        If $o_Link.tabIndex = 1 Then
            $o_NewMessage = $o_Link
            ExitLoop
        EndIf
    Next
    
    If Not IsObj($o_NewMessage) Then Exit
    
    _IEAction($o_NewMessage, "click")
    _IELoadWait($o_IE)
    
    $o_Form = _IEFormGetObjByName($o_IE, "composeform")
    $o_To = _IEFormElementGetObjByName($o_Form, "to")
    $o_Subject = _IEFormElementGetObjByName($o_Form, "subject")
    $o_Body = _IEFormElementGetObjByName($o_Form, "body")
    
    $o_Links = _IELinkGetCollection($o_IE)
    For $o_Link In $o_Links
        If $o_Link.tabIndex = 1 Then
            $o_Send = $o_Link
            ExitLoop
        EndIf
    Next

    _IEFormElementSetValue($o_To, $s_To)
    _IEFormElementSetValue($o_Subject, $s_Subject)
    _IEFormElementSetValue($o_Body, $s_Body)
    _IEAction($o_Send, "click")
    _IELoadWait($o_IE)
    
    _IEImgClick($o_IE, "Sign out of .NET Passport sites", "alt")
    _IEQuit($o_IE)

EndFunc   ;==>_Hotmail