Is there better way to write this function?

[E1M1]

Is there better way to write that function? I know there is always better way to make that script. But I ran out of ideas :S

Func _InvertColor($iColor, $mode = 2)
    $iColor = String(Hex($iColor, 6))
    If $mode = 0 Then
        $RColor = StringTrimLeft(StringTrimRight($iColor, 4), 0)
        $GColor = StringTrimLeft(StringTrimRight($iColor, 2), 2)
        $BColor = StringTrimLeft(StringTrimRight($iColor, 0), 4)
        $InvertedRColor = Hex(255 - Dec($RColor), 2)
        $InvertedGColor = Hex(255 - Dec($GColor), 2)
        $InvertedBColor = Hex(255 - Dec($BColor), 2)
    ElseIf $mode = 1 Then
        $InvertedBColor = StringTrimLeft(StringTrimRight($iColor, 4), 0)
        $InvertedGColor = StringTrimLeft(StringTrimRight($iColor, 2), 2)
        $InvertedRColor = StringTrimLeft(StringTrimRight($iColor, 0), 4)
    ElseIf $mode = 2 Then   
        $BColor = StringTrimLeft(StringTrimRight($iColor, 4), 0)
        $GColor = StringTrimLeft(StringTrimRight($iColor, 2), 2)
        $RColor = StringTrimLeft(StringTrimRight($iColor, 0), 4)
        $InvertedRColor = Hex(255 - Dec($RColor), 2)
        $InvertedGColor = Hex(255 - Dec($GColor), 2)
        $InvertedBColor = Hex(255 - Dec($BColor), 2)
    EndIf
    $InvertColor = $InvertedRColor & $InvertedGColor & $InvertedBColor
    Return "0x" & $InvertColor
EndFunc   ;==>_InvertColor

[weaponx]

ConsoleWrite(_InvertColor(0x000000))
Func _InvertColor($iColor)

    Return  0xFFFFFF - $icolor
EndFunc   ;==>_InvertColor

[martin]

ConsoleWrite(_InvertColor(0x000000))
Func _InvertColor($iColor)

    Return  0xFFFFFF - $icolor
EndFunc   ;==>_InvertColor

I don't think that will work, or at least not very often.

Sorry misunderstood what was happening there, it's nice and simple.

There are some approaches in this thread.

Edited June 11, 2009 by martin

[E1M1]

ConsoleWrite(_InvertColor(0x000000))
Func _InvertColor($iColor)

    Return  0xFFFFFF - $icolor
EndFunc   ;==>_InvertColor

it returns lightblue (blue + green) from red

[Malkey]

Try this.

expandcollapse popup

;
Local $col = 0x7AB809

ConsoleWrite(_InvertColor($col, 0) & @CRLF)
ConsoleWrite(_InvertColor($col, 1) & @CRLF)
ConsoleWrite(_InvertColor($col, 2) & @CRLF & @CRLF)

ConsoleWrite(_InvertColorA($col, 0) & @CRLF)
ConsoleWrite(_InvertColorA($col, 1) & @CRLF)
ConsoleWrite(_InvertColorA($col, 2) & @CRLF)

Func _InvertColor($iColor, $mode = 0)
    Switch $mode
        Case 0
            Return "0x" & Hex(0xFFFFFF - $iColor, 6)
        Case 1
            Return "0x" & StringRegExpReplace(Hex($iColor, 6), "(.{2})(.{2})(.{2})", "\3\2\1")
        Case 2
            Return "0x" & StringRegExpReplace(Hex(0xFFFFFF - $iColor, 6), "(.{2})(.{2})(.{2})", "\3\2\1")
    EndSwitch
EndFunc  ;==>_InvertColor

Func _InvertColorA($iColor, $mode = 2)
    $iColor = String(Hex($iColor, 6))
    If $mode = 0 Then
        $RColor = StringTrimLeft(StringTrimRight($iColor, 4), 0)
        $GColor = StringTrimLeft(StringTrimRight($iColor, 2), 2)
        $BColor = StringTrimLeft(StringTrimRight($iColor, 0), 4)
        $InvertedRColor = Hex(255 - Dec($RColor), 2)
        $InvertedGColor = Hex(255 - Dec($GColor), 2)
        $InvertedBColor = Hex(255 - Dec($BColor), 2)
    ElseIf $mode = 1 Then
        $InvertedBColor = StringTrimLeft(StringTrimRight($iColor, 4), 0)
        $InvertedGColor = StringTrimLeft(StringTrimRight($iColor, 2), 2)
        $InvertedRColor = StringTrimLeft(StringTrimRight($iColor, 0), 4)
    ElseIf $mode = 2 Then
        $BColor = StringTrimLeft(StringTrimRight($iColor, 4), 0)
        $GColor = StringTrimLeft(StringTrimRight($iColor, 2), 2)
        $RColor = StringTrimLeft(StringTrimRight($iColor, 0), 4)
        $InvertedRColor = Hex(255 - Dec($RColor), 2)
        $InvertedGColor = Hex(255 - Dec($GColor), 2)
        $InvertedBColor = Hex(255 - Dec($BColor), 2)
    EndIf
    $InvertColor = $InvertedRColor & $InvertedGColor & $InvertedBColor
    Return "0x" & $InvertColor
EndFunc  ;==>_InvertColorA
;

[weaponx]

it returns lightblue (blue + green) from red

I'm not sure if you're saying it's wrong but it works for me.

Red 0xff0000 -> Cyan 0x00ffff

Green 0x00ff00 -> Magenta 0xff00ff

Blue 0x0000ff -> Yellow 0xffff00

Edited June 11, 2009 by weaponx