Multiple GUI

[GodlessSinner]

#include <WinAPI.au3>
#include <WindowsConstants.au3>
#include <StaticConstants.au3>
#include <GUIConstantsEx.au3>
$Form = GUICreate("Main window", 260, 99, 542, 678, BitOR($WS_POPUP,$WS_BORDER))
Opt("TrayMenuMode",1)
$open = TrayCreateItem("About")
TrayCreateItem("")
$exititem = TrayCreateItem("Exit")

GUISetState(@SW_SHOW)
$Form1 = GUICreate("About", 240, 127, 500, 500, BitOR($WS_SYSMENU,$WS_CAPTION,$WS_POPUP,$WS_POPUPWINDOW,$WS_BORDER,$WS_CLIPSIBLINGS))

While 1
        $nMsg = GUIGetMsg(1)
        $tray = TrayGetMsg()
        Switch $tray
            Case $exititem
                Exit
            Case $open
                GUISetState(@SW_SHOW,$Form1)
                WinSetOnTop ($Form, "", 0)
        EndSwitch
        Select
        Case $nMsg[0] = $GUI_EVENT_CLOSE
        If $nMsg[1] = $Form1 Then
            GUISetState(@SW_HIDE, $Form1)
        ElseIf $nMsg[1] = $Form Then
            Exit
        EndIf
        Case $GUI_EVENT_PRIMARYDOWN
            _SendMessage($Form, $WM_SYSCOMMAND, 0xF012, 0)
EndSelect
    WEnd

Why "About" window can't be active? And how to prevent from clicking in main window when "About" is shown?

thanks.

[Melba23]

Godless,

Your SendMessage is constantly reactivating the main window. Try testing to see if the "About" window is active before sending. As to preventing clicking in the main window, just Disable/Enable it when the "About" window shows:

expandcollapse popup

#include <WinAPI.au3>
#include <WindowsConstants.au3>
#include <StaticConstants.au3>
#include <GUIConstantsEx.au3>

Opt("TrayMenuMode", 1)

$open = TrayCreateItem("About")
TrayCreateItem("")
$exititem = TrayCreateItem("Exit")

$Form = GUICreate("Main window", 260, 99, 542, 678, BitOR($WS_POPUP, $WS_BORDER))
GUISetState(@SW_SHOW)

$Form1 = GUICreate("About", 240, 127, 500, 500, BitOR($WS_SYSMENU, $WS_CAPTION, $WS_POPUP, $WS_POPUPWINDOW, $WS_BORDER, $WS_CLIPSIBLINGS))
GUISetState(@SW_HIDE)

While 1

    $tray = TrayGetMsg()
    Switch $tray
        Case $exititem
            Exit
        Case $open
            GUISetState(@SW_SHOW, $Form1)
            WinSetOnTop($Form, "", 0)
            GUISetState(@SW_DISABLE, $Form)
    EndSwitch

    $nMsg = GUIGetMsg(1)
    Select
        Case $nMsg[0] = $GUI_EVENT_CLOSE
            If $nMsg[1] = $Form1 Then
                GUISetState(@SW_HIDE, $Form1)
                GUISetState(@SW_ENABLE, $Form)
            ElseIf $nMsg[1] = $Form Then
                Exit
            EndIf
        Case $GUI_EVENT_PRIMARYDOWN
            If BitAND(WinGetState($Form1), 2) <> 2 Then _SendMessage($Form, $WM_SYSCOMMAND, 0xF012, 0)
    EndSelect
WEnd

M23

Edit: Speeling

Edited August 15, 2009 by Melba23