Autoscroll broken?

[Rorka]

I need it to autoscroll:

This is some reconstruction code:

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 222, 278, 192, 124)
$Edit1 = GUICtrlCreateEdit("", 16, 8, 185, 217, BitOR($ES_AUTOVSCROLL,$ES_READONLY,$ES_WANTRETURN,$WS_VSCROLL))
GUICtrlSetData(-1, "Edit1")
$Button1 = GUICtrlCreateButton("GO", 16, 232, 187, 25, $WS_GROUP)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
            While 1
                GUICtrlSetData($Edit1, GUICtrlRead($Edit1) & "Testing")
            WEnd
    EndSwitch
WEnd

I dunno why it dont work

[PsaltyDS]

Vertical scroll happens when the control receives "{ENTER}" and you set it to $ES_READONLY so it isn't receiving that even if you ControlSend() it.

[CodyBarrett]

i use

_GUICtrlEdit_AppendText ($hWnd,'Text')

that auto scrolls it... instead of using Guictrlsetdata ($ID, Guictrlread ($ID) & @CR & 'Text') WHICH DOESN'T auto scroll

[Skrip]

_GUICtrlEdit_LineScroll($dCtrl, 0, _GUICtrlEdit_GetLineCount($dCtrl))

Replace $dctrl and slap that into a loop or somethin.

[PsaltyDS]

i use

_GUICtrlEdit_AppendText ($hWnd,'Text')

that auto scrolls it... instead of using Guictrlsetdata ($ID, Guictrlread ($ID) & @CR & 'Text') WHICH DOESN'T auto scroll

Hey, I like that one. I tried it this way:

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiEdit.au3>

$Form1 = GUICreate("Form1", 222, 278, 192, 124)
$Edit1 = GUICtrlCreateEdit("", 16, 8, 185, 217, BitOR($ES_AUTOVSCROLL, $ES_READONLY, $ES_WANTRETURN, $WS_VSCROLL))
GUICtrlSetData(-1, "Edit1")
$Button1 = GUICtrlCreateButton("GO", 16, 232, 187, 25)
GUISetState(@SW_SHOW)
$n = 1

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
            For $n = $n To $n + 100
                _GUICtrlEdit_AppendText($Edit1, ", " & $n & ", Testing")
            Next
    EndSwitch
WEnd

[CodyBarrett]

ya.. after some searching on a project of my own... i came across that function in one of the topics here on the forum... can't remember off the top of my head... but i was looking for a GUIstyle that would do that.. but came across this instead i like it its simpler and has less code to write