How to access IE InPrivate window

[Nad]

Hi,

Could anyone please let me know how can I open a IE InPrivate window and send an address to it? Does it have different properties? Or AutoIT can not access it at all? All my attempts are failed.

I tried this script

#include <IE.au3>

$oIE = _IECreate ("")

Send ("^+P")

Sleep (100)

$oIE1 = _IEAttach ("", "instance", 2)

_IENavigate ($oIE1, "http://website.com")

Thanks in advance.

Cheers

Nad

[Nad]

Wow it seems no one interested in inPrivate windows on IE. Well I was too new to find it out by myself.

Here is the script if any one interested

$oIE = _IECreate ("")

Send ("^+P")

Sleep (1000)

Send("http://google.com")

send("{ENTER}")

Since this is a inPrivate window created by pressing CTRL+SHIFT+P on IE, I do not know how to get the handler of that window. So could not get _IEAttach and _IEGetObjByName functions to work. Anyone to give me a clue?

Thanks guys in advance

Nad

[DaleHohm]

Here's something to get you started... not sure if there is a COM method to create the private window... perhaps as a flag to Navigate2, but I haven't looked.

#include <IE.au3>

$oIEtmp = _IECreate ("")
Send ("^+P")
Sleep (4000)
$oIE = _IEAttach("InPrivate")
_IELoadWait($oIE)
_IENavigate($oIE, "http://google.com")

Dale

[SmOke_N]

I couldn't find anything on Navigate2 like Dale suggested there might be ( But then again, I don't know as much as he does when it comes to it ).

This may help, however there's not much error checking involved, and I'm not quite sure how reliable it would be if you had multiple instances running.

expandcollapse popup

#include <IE.au3>

Global $oIE = _IEInPrivateCreate("www.google.com", 2)
If @error Then
    If @error = 2 Then ProcessClose(@extended)
    Exit 1
EndIf
_IELoadWait($oIE)

_IENavigate($oIE, "www.yahoo.com")

Func _IEInPrivateCreate($s_url, $i_timeout = -1) ; Simple version, you can add all the other stuff if you like ($i_timeout is in secs).
    Local $s_random = "about:InPrivate " & Random(1000000, 99999999, 1) & "-" & Random(1000000, 99999999, 1)
    If $s_url = "" Then $s_url = "about:InPrivate"

    Local $i_pid = Run('"' & @ProgramFilesDir & '\Internet Explorer\iexplore.exe" -private "' & $s_random & '"')
    If $i_pid = 0 Then Return SetError(1, 0, 0)

    If StringInStr("|default|-1|", "|" & $i_timeout & "|") Then $i_timeout = 0

    Local $h_wnd, $o_shell, $o_shell_wins, $i_timer

    If $i_timeout > 0 Then $i_timer = TimerInit()
    While 1

        If $i_timeout And TimerDiff($i_timer) / 1000 > $i_timeout Then
            Return SetError(2, $i_pid, 0)
        EndIf

        $h_wnd = WinGetHandle($s_random)
        If $h_wnd Then ExitLoop
        Sleep(10)
    WEnd

    $o_shell = ObjCreate("Shell.Application")
    If IsObj($o_shell) Then
        $o_shell_wins = $o_shell.Windows

        For $o_shell_win In $o_shell_wins
            ; IE.au3 checks for IWebBrowser as well as IWebBrowser2 with __IEIsObjType
            ; This fails with my outlook with "hwnd" property
            ; So if its 100% neccessary, you'll need to find a work around
            If String(ObjName($o_shell_win)) = "IWebBrowser2" Then
                If $o_shell_win.hwnd = $h_wnd Then
                    Return SetError(0, $i_pid, $o_shell_win)
                EndIf
            EndIf
        Next
    EndIf

    Return SetError(3, $i_pid, 0)
EndFunc

Edit:

Added timeout param, and @extended ( with anything other than @error = 1 ) will return the pid of the ie exe.

Edit2:

Was using the url and .LocationURL for hwnd verification, however, if there's a redirect this would fail.

Using __IEIsObjType() fails when using outlook, so I am just using ObjectName() + IWebBrowser2

Edited January 11, 2010 by SmOke_N

[Nad]

Here's something to get you started... not sure if there is a COM method to create the private window... perhaps as a flag to Navigate2, but I haven't looked.

#include <IE.au3>

$oIEtmp = _IECreate ("")
Send ("^+P")
Sleep (4000)
$oIE = _IEAttach("InPrivate")
_IELoadWait($oIE)
_IENavigate($oIE, "http://google.com")

Dale

Thanks Dale and SmOke_N,

I've just implemented my code by using "instance" instead of using the title (it didn't work for me)

Here is the code if someone interested. This script will put fake votes on a protected online voting system.

Yah yah I know I'm being cheeky. Well... its fun.

#include <IE.au3>

$oIE = _IECreate ("")

For $i = 1 to 500 Step 1

Send ("^+P")

Sleep (1000)

Send("http://website/")

send("{ENTER}")

sleep(5000)

$oIE1 = _IEAttach ("", "instance", 2)

$oID = "radioObjectID" ;got this using fire bug

$oSubmitID = "buttonObjectID" ;got this using fire bug

$oMR = _IEGetObjByName($oIE1, $oID, 0)

$oMR.checked = True

$oSubmit = _IEGetObjByName ($oIE1, $oSubmitID)

_IEAction ($oSubmit, "click")

sleep(2000)

_IEQuit ($oIE1)

sleep(1000)

Next

Edited January 12, 2010 by Nad