Centered popup GUI

[Edifice]

Let's say I have a GUI 500x500 pixels and I have a second GUI that pops up 100x100 pixels.

How can I then make the popupGUI always pop "from the center" of my main GUI?

Any help is greatly appreciated - I feel like I've tried everything.

[Melba23]

Edifice,

Just get your main GUI position and then do a bit of maths:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$hPopupGUI = 9999

$hGUI = GUICreate("Test", 500, 500)

$hButton = GUICtrlCreateButton("Popup", 10, 10, 80, 30)

GUISetState()

While 1

    $aMsg = GUIGetMsg(1)
    Switch $aMsg[1]
        Case $hGUI
            Switch $aMsg[0]
                Case $GUI_EVENT_CLOSE
                    Exit
                Case $hButton
                    $apos = WinGetPos($hGUI)
                    $iHpos = ($aPos[2] - 100) / 2 + $aPos[0] - 3
                    $iVPos = ($aPos[3] - 100) / 2 + $aPos[1] - 20

                    $hPopupGUI = GUICreate("Popup", 100, 100, $iHpos, $iVPos)
                    GUISetState()
            EndSwitch
        Case $hPopupGUI
            If $aMsg[0] = $GUI_EVENT_CLOSE Then GUIDelete($hPopupGUI)
    EndSwitch

WEnd

23

[Edifice]

Thanks! This works really great!

I wasn't sure how to get to position, and also I didn't try to delete and create the GUI - only show and hide it.

Really nicely done. Thanks again.

[Melba23]

Edifice,

You can use @SW_HIDE/SHOW if you wish:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$hPopupGUI = 9999

$hGUI = GUICreate("Test", 500, 500)

$hButton = GUICtrlCreateButton("Popup", 10, 10, 80, 30)

GUISetState()

$hPopupGUI = GUICreate("Popup", 100, 100)
GUISetState(@SW_HIDE)

While 1

    $aMsg = GUIGetMsg(1)
    Switch $aMsg[1]
        Case $hGUI
            Switch $aMsg[0]
                Case $GUI_EVENT_CLOSE
                    Exit
                Case $hButton
                    $apos = WinGetPos($hGUI)
                    $iHpos = ($aPos[2] - 100) / 2 + $aPos[0] - 3
                    $iVPos = ($aPos[3] - 100) / 2 + $aPos[1] - 20
                    WinMove($hPopupGUI, "", $iHpos, $iVPos)
                    GUISetState(@SW_SHOW, $hPopupGUI)


            EndSwitch
        Case $hPopupGUI
            If $aMsg[0] = $GUI_EVENT_CLOSE Then GUISetState(@SW_HIDE, $hPopupGUI)
    EndSwitch

WEnd

M23