Detect focus

[PhilHibbs]

Can I detect a change of focus between edit boxes? I'm trying to set the default button depending on which edit box has focus. This doesn't work:

IF BitAnd( GUICtrlGetState($ePass), $GUI_FOCUS ) Then
            GUICtrlSetState($bLaunch, $GUI_DEFBUTTON)
        ElseIf BitAnd( GUICtrlGetState($ePass_2), $GUI_FOCUS ) Then
            GUICtrlSetState($bLaunch_2, $GUI_DEFBUTTON)
        EndIf

When I diagnose this, GUICtrlGetState is returning 80, but $GUI_FOCUS is 256, so this is clearly wrong. I don't think GUICtrlGetState is going to tell me if the control has focus.

[Melba23]

PhilHibbs,

I would do it this way:

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>

$hGUI = GUICreate("Test", 500, 500)

$hEdit_1 = GUICtrlCreateEdit("", 10, 10, 400, 140)
$hEdit_1_Handle = GUICtrlGetHandle(-1)
$hButton_1 = GUICtrlCreateButton("Edit 1", 10, 160, 80, 30)

$hEdit_2 = GUICtrlCreateEdit("", 10, 210, 400, 140)
$hEdit_2_Handle = GUICtrlGetHandle(-1)
$hButton_2 = GUICtrlCreateButton("Edit 1", 10, 360, 80, 30)

GUISetState()

_WinAPI_SetFocus($hEdit_1_Handle)
GUICtrlSetState($hButton_2, $GUI_DISABLE)

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    Switch _WinAPI_GetFocus()
        Case $hEdit_1_Handle
            If BitAnd(GUICtrlGetState($hButton_1), $GUI_DISABLE) = $GUI_DISABLE Then GUICtrlSetState($hButton_1, $GUI_ENABLE)
            If BitAnd(GUICtrlGetState($hButton_2), $GUI_ENABLE) = $GUI_ENABLE Then GUICtrlSetState($hButton_2, $GUI_DISABLE)
        Case $hEdit_2_Handle
            If BitAnd(GUICtrlGetState($hButton_2), $GUI_DISABLE) = $GUI_DISABLE Then GUICtrlSetState($hButton_2, $GUI_ENABLE)
            If BitAnd(GUICtrlGetState($hButton_1), $GUI_ENABLE) = $GUI_ENABLE Then GUICtrlSetState($hButton_1, $GUI_DISABLE)
    EndSwitch

WEnd

M23

[Andreik]

Or like this:

$Main = GUICreate("Example",400,250)
$Edit1 = GUICtrlCreateEdit("",5,5,190,190)
$Edit2 = GUICtrlCreateEdit("",205,5,190,190)
$Button1 = GUICtrlCreateButton("Launch",50,210,100,30)
$Button2 = GUICtrlCreateButton("Launch",250,210,100,30)
GUISetState(@SW_SHOW,$Main)

While True
    If GUIGetMsg() = -3 Then Exit
    If ControlGetFocus("Example") = "Edit1" Then
        GUICtrlSetState($Button1,512)
    ElseIf ControlGetFocus("Example") = "Edit2" Then
        GUICtrlSetState($Button2,512)
    EndIf
    Sleep(10)
WEnd

[PhilHibbs]

Thanks, this works:

IF _WinAPI_GetFocus() = GUICtrlGetHandle($ePass) Then
            GUICtrlSetState($bLaunch, $GUI_DEFBUTTON)
        ElseIf _WinAPI_GetFocus() = GUICtrlGetHandle($ePass_2) Then
            GUICtrlSetState($bLaunch_2, $GUI_DEFBUTTON)
        EndIf

I'll capture the GUICtrlGetHandle for efficiency.