How to use dynamic menu?

[E1M1]

Hello, how I can use dynamic menu? I create meny by reading elements from file, but how I bind action for every menu item?

I am used to bind action like this

Case $MenuItem1
 Code()

but if i create menu dynamically then I cant use it like that.

Also I have 2 static menus. I want make my code so that both dynamic and static menus would work.

Any ideas/suggestions?

Edit: Can I use array some how? Will it help?

Thanks

Edited April 1, 2010 by E1M1

[jchd]

For controls, place your dynamically-created control handles in an array an then use $MyControls[23] to refer to the 24-th element created, for instance. Of course you have to organize indexes rigorously to avoid getting lost about where that checkbox handle has been stored.

But how can you create more than one menu is a bit beyond me.

[E1M1]

but if i don know number of elements then i can write

case $MyControls[23] can i get clicked item's text or array's Nr?

[jchd]

I don't get it. If you create elements yourself, you know how many you create!

Do you have simple example code of what you're doing?

[E1M1]

$Edit = GUICtrlCreateMenu("Edit")
$EditSettings = GUICtrlCreateMenu("Settings",$Edit)
$EditSettingSettings = GUICtrlCreateMenuItem('Settings', $EditSettings)
$EditSettingSequence= GUICtrlCreateMenuItem('Sequence', $EditSettings)
$EditBosses = GUICtrlCreateMenu("Bosses",$Edit)
$EditBuilds = GUICtrlCreateMenu("Builds",$Edit)
$builds = _FileListToArray($BuildsDir,"*.lua",1)
for $i = 1 To $builds[0]
    GUICtrlCreateMenuItem($builds[$i],$EditBuilds)
Next
$bosses = _FileListToArray($bossDir,"*.lua",1)
for $i = 1 To $bosses[0]
    GUICtrlCreateMenuItem($bosses[$i],$EditBosses)
Next

[martin]

$Edit = GUICtrlCreateMenu("Edit")
$EditSettings = GUICtrlCreateMenu("Settings",$Edit)
$EditSettingSettings = GUICtrlCreateMenuItem('Settings', $EditSettings)
$EditSettingSequence= GUICtrlCreateMenuItem('Sequence', $EditSettings)
$EditBosses = GUICtrlCreateMenu("Bosses",$Edit)
$EditBuilds = GUICtrlCreateMenu("Builds",$Edit)
$builds = _FileListToArray($BuildsDir,"*.lua",1)
for $i = 1 To $builds[0]
    GUICtrlCreateMenuItem($builds[$i],$EditBuilds)
Next
$bosses = _FileListToArray($bossDir,"*.lua",1)
for $i = 1 To $bosses[0]
    GUICtrlCreateMenuItem($bosses[$i],$EditBosses)
Next

I think jchd was suggesting something like this.

$Edit = GUICtrlCreateMenu("Edit")
$EditSettings = GUICtrlCreateMenu("Settings",$Edit)
$EditSettingSettings = GUICtrlCreateMenuItem('Settings', $EditSettings)
$EditSettingSequence= GUICtrlCreateMenuItem('Sequence', $EditSettings)
$EditBosses = GUICtrlCreateMenu("Bosses",$Edit)
$EditBuilds = GUICtrlCreateMenu("Builds",$Edit)
$builds = _FileListToArray($BuildsDir,"*.lua",1)
Global $BuilMenuItems[$builds[0]],$BossesMenuItems[$bosses[0]]
for $i = 1 To $builds[0]
    $BuilMenuItems[$i - 1] = GUICtrlCreateMenuItem($builds[$i],$EditBuilds)
Next
$bosses = _FileListToArray($bossDir,"*.lua",1)
for $i = 1 To $bosses[0]
    $BossesMenuItems[$i - 1] = GUICtrlCreateMenuItem($bosses[$i],$EditBosses)
Next

[jchd]

Here's a way:

expandcollapse popup

#include <GUIConstantsEx.au3>

GUICreate("Menu test", 800, 600, 200, 200)
Local $Edit = GUICtrlCreateMenu("Edit")
Local $EditSettings = GUICtrlCreateMenu("Settings", $Edit)
Local $EditSettingSettings = GUICtrlCreateMenuItem('Settings', $EditSettings)
Local $EditSettingSequence= GUICtrlCreateMenuItem('Sequence', $EditSettings)
Local $EditBosses = GUICtrlCreateMenu("Bosses", $Edit)
Local $EditBuilds = GUICtrlCreateMenu("Builds", $Edit)
GUISetState()

Local $builds = _FileListToArray(@ScriptDir, "*.au3", 1)
Local $buildsHdl[$builds[0] + 1]
For $i = 1 To $builds[0]
    $buildsHdl[$i] = GUICtrlCreateMenuItem($builds[$i], $EditBuilds)
Next
Local $bosses = _FileListToArray(@ScriptDir & '\..\include', "*.au3", 1)
Local $bossesHdl[$bosses[0] + 1]
For $i = 1 To $bosses[0]
    $bossesHdl[$i] = GUICtrlCreateMenuItem($bosses[$i], $EditBosses)
Next

Local $msg

While 1
    $msg = GUIGetMsg()

    If $msg = $GUI_EVENT_CLOSE Then
        Exit
    Else
        Local $n = _ArraySearch($buildsHdl, $msg, 1)
        If $n > 0 Then
            MsgBox(0, "Tracking menu items", "You selected " & $Builds[$n])
        Else
            $n = _ArraySearch($bossesHdl, $msg, 1)
            If $n > 0 Then
                MsgBox(0, "Tracking menu items", "You selected " & $bosses[$n])
            EndIf
        EndIf
    EndIf
WEnd

[E1M1]

great thanks. for showing I did it a bit other way but...

..
..
..$EditBosses = GUICtrlCreateMenu("Bosses",$Edit)
$EditBuilds = GUICtrlCreateMenu("Builds",$Edit)
$builds = _FileListToArray($BuildsDir,"*.lua",1)
for $i = 1 To $builds[0]
    GUICtrlCreateMenuItem($builds[$i],$EditBuilds)
Next
$bosses = _FileListToArray($bossDir,"*.lua",1)
for $i = 1 To $bosses[0]
    GUICtrlCreateMenuItem($bosses[$i],$EditBosses)
Next

dim $newarray[$builds[0]+$bosses[0]]
for $i = 0 To $builds[0] -1
    $newarray[$i] = $builds[$i+1]
next
for $i = $builds[0]+1 To ($builds[0]+$bosses[0])
    $newarray[$i-1] = $bosses[($i-$builds[0])]
next
..
..
..

..
..
..      Case $FurnaceOfPain
            Chat('FurnaceOfPain', 1)
        Case $ubertristram
            Chat('UberTristram', 1)
    EndSwitch
    If $msg <> 0 and $msg <> -11 and $msg <> -8 Then
    MsgBox(0,$msg,$newarray[$msg-287]); I have 287 static elements
    EndIf

Edited April 1, 2010 by E1M1

[jchd]

You got the idea. Now as you say, you arrange storage/retrieval the way that fits the application best. As long as you can access control IDs coveniently and link them to your dynamic items, you have much room for creativity.