Compare strings with wildcards and check if it match

[Chris86]

Hello, Does anyone know an easy way to check string if its match with another string, that works with wildcards?

$URL = "http://something.something.com/something"
$BlockedURLS = "http://*.something.com/*|http://something2.com/ads*"

Edited April 7, 2010 by Chris86

[Chris86]

anyone?

[Valuater]

maybe if you explained more someone might understand just what you are thinking

8)

[Chris86]

Ok, Im trying to find a way to check if a url match any of the blocked urls

All the blocked urls are in an array, but how can I compare them with wildcards etc?

$URL = "http://something.something.com/something"
$BlockedURLS = "http://*.something.com/*|http://something2.com/ads*"
$array = StringSplit($BlockedURLS, "|")
For $array = 1 to $array[0] Step 1
If 
;COMPARE $URL with $Array
    MsgBox(0,"", "URL match, cutting connection")
else
MsgBox(0,"", "No match, let it pass")
endif
Next

Edited April 7, 2010 by Chris86

[z0mgItsJohn]

Here's an example that might help you get started :

Global $Blocked = 'something.com|google.com|autoitscript.com'

MsgBox (0, 'Test','Blocked : ' & _IsBlocked ('http://something.something.com/something'))
MsgBox (0, 'Test','Blocked : ' & _IsBlocked ('http://www.google.com/search?client=firefox-a&rls=org.mozilla%3Aen-US%3Aofficial&channel=s&hl=en&source=hp&q=lol&btnG=Google+Search'))
MsgBox (0, 'Test','Blocked : ' & _IsBlocked ('http://www.autoitscript.com/forum/index.php?showtopic=112752'))
MsgBox (0, 'Test','Blocked : ' & _IsBlocked ('http://lol.com/'))

Func _IsBlocked ($URL)
    $Split = StringSplit ($Blocked, '|')
    For $A = 1 To $Split[0]
        If StringInStr ($URL, $Split[$A]) Then Return 1
    Next
EndFunc

Hope it helps! =]

- John

Edited April 7, 2010 by John2010zz

[jchd]

Avoid bumping under 24h please.

Now to answer your question, you may succeed in doing what you want with regexps. The issue will be massaging your blocking patterns to fit RegExp grammar.

Try first replacing * by .* and . by \. in your patterns. Enclose them in perenthesis and concatenate them with |

You may need more replacements.

Quick untested try:

$URL = "http://something.something.com/something"
$BlockedURLS = "http://*.something.com/*|http://something2.com/ads*"
$BlockedURLS = StringReplace($BlockedURLS, ".", "\.")
$BlockedURLS = StringRegExpReplace($BlockedURLS, "(?<!\\)\*", "\.\*")
$array = StringSplit($BlockedURLS, "|")
$cut = False
For $i = 1 to $array[0]
    ;COMPARE $URL with $Array
    ConsoleWrite("comparing " & $url & " against pattern " & $array[$i] & @LF)
    $cut = $cut Or StringRegExp($URL, $array[$i])
Next
If $cut Then
    MsgBox(0,"", "URL match, cutting connection")
Else
    MsgBox(0,"", "Go ahead")
EndIf

You may as well concatenate as I said before. For instance:

$URL = "http://something.something.com/something"
$BlockedURLS = "http://*.something.com/*|http://something2.com/ads*"
$BlockedURLS = StringReplace($BlockedURLS, ".", "\.")
$BlockedURLS = StringRegExpReplace($BlockedURLS, "(?<!\\)\*", "\.\*")
$BlockedURLS = '(' & StringReplace($BlockedURLS, "|", ")|(") & ')'

ConsoleWrite("comparing " & $url & " against pattern " & $BlockedURLS & @LF)
$cut = StringRegExp($URL, $BlockedURLS)
If $cut Then
    MsgBox(0,"", "URL match, cutting connection")
Else
    MsgBox(0,"", "Go ahead")
EndIf

But keep in mind that doing so with hundreds of individual Urls all concatenated in an alternation pattern, then it will drag feet considerably!

Edit: also beware of referer Urls as you could block access to legitimate Urls that have blocked Urls as referers. How could users have got there previously is a good question.

Edited April 7, 2010 by jchd

[Chris86]

Ok This will help me alot thanks