Server / Client

[FinalVersion]

If I send "MsgBox" with the client, it works. But then if I try to send anything a second time, it won't work. Why?

Server

TCPStartup()
$mainSock = TCPListen("127.0.0.1", 1030)
If $mainSock = -1 Then Exit

$sockClient = -1
Do
    $sockClient = TCPAccept($mainSock)
Until $sockClient <> -1

$ret = ""
While 1
    $ret = TCPRecv($sockClient, 1000)
    Switch $ret
        Case "MsgBox"
            MsgBox(0, "", "MsgBox")
            $ret = ""
        Case "Close"
            ExitLoop
            $ret = ""
    EndSwitch
WEnd

TCPCloseSocket($sockClient)
TCPShutdown()

Client

TCPStartup()
$sockMain = TCPConnect("127.0.0.1", 1030)
If $sockMain = -1 Then Exit

$sNode = InputBox("", "")
TCPSend($sockMain, $sNode)

TCPCloseSocket($sockMain)
TCPShutdown()

[ChrisL]

Updated Server Code

$IP = "192.168.2.102"

TCPStartup()
$mainSock = TCPListen($IP, 1030)
If $mainSock = -1 Then Exit

$sockClient = -1

$ret = ""
While 1
    If $sockClient = -1 then
        $sockClient = TCPAccept($mainSock)
        _DebugWrite("sockMain = " & $sockClient)
    Else
        $ret = TCPRecv($sockClient, 1000)
        If @error then $sockClient = -1 ;The connection has been closed
        _DebugWrite("Ret = " & $Ret)
        Switch $ret
            Case "MsgBox"
                MsgBox(0, "", "MsgBox")
                $ret = ""
            Case "Close"
                Exitloop
        EndSwitch

    EndIf
WEnd

TCPCloseSocket($mainSock)
TCPShutdown()

Func _DebugWrite($vStr = "")
    ConsoleWrite($vStr & @crlf)
EndFunc

Edited April 18, 2010 by ChrisL