FileWriteToLine Problem

[dobbelina]

Hi !

Example to illustrate the problem:

The script is searching for the word "dog".

If "dog" is not found it will look for the word "cat" and

add "dog" beneath it.

If "dog" is found the script wont execute the function,

so to safeguard against multiple writes.

The script does everything perfectly except for one thing,

It deletes the word underneath where "dog" is inserted.

Therefore i need a linefeed or something, so i can keep

the "fish" (See example)

#Include <File.au3>
Global $success = False
$myfile = "C:\Test.txt"
$file = FileRead($myfile, FileGetSize($myfile))
$file = StringSplit($file, @CRLF, 1)
for $i = 0 to $file[0] Step 1
    If StringInStr($file[$i], "dog") Then
    $success = True
         ExitLoop
    EndIf
Next
if $success = Not True Then
   MsgBox(0, "Not fund", "Line not found, so lets write")
    _test()
EndIf
Func _test()
for $i = 0 to $file[0] Step 1
    If StringInStr($file[$i], "cat") Then

           _FileWriteToLine($myfile, $i+1,"dog", 1)
      EndIf
  Next
  EndFunc

Original Test.txt:

monkey

bird

cat

fish

crocodile

Becomes: (fish is gone)

monkey

bird

cat

dog

crocodile

But i want:

monkey

bird

cat

dog

fish

crocodile

It's cracking me up this problem, any help is much appreciated !

[jchd]

Like this:

#Include <Array.au3>

Local Const $myfile = "Test.txt"        ;; I had to change that
Local Const $cat = "cat"
Local Const $dog = "dog"
Local $lines

_FileReadToArray($myfile, $lines)
Local $index = _ArraySearch($lines, $cat, 1)
If $index = -1 Then $index = UBound($lines) - 1
_ArrayInsert($lines, $index + 1, $dog)
_FileWriteFromArray($myfile, $lines, 1)

[hawky358]

The _Filewritetoline() function already has this built in

Here's the syntax:

_FileWriteToLine($sFile, $iLine, $sText[, $fOverWrite = 0])

change _FileWriteToLine($myfile, $i+1,"dog", 1)

to _FileWriteToLine($myfile, $i+1,"dog", 0)

or _FileWriteToLine($myfile, $i+1,"dog")

Edited May 12, 2010 by hawky358

[dobbelina]

Ahh, thank you very much!

Now it works as i want.

[Sritra]

Ok, what am i doing wrong?

I just wanted to check if my _filewritetoline works, but it doesn't seem so

#Include 
Global $success = False
$myfile = "C:\Users\Fabi\Desktop\elements\test.txt"
$file = FileRead($myfile, FileGetSize($myfile))
$file = StringSplit($file, @CRLF, 1)
for $i = 0 to $file[0] Step 1
If StringInStr($file[$i], "dog") Then
$success = True
ExitLoop
EndIf
Next
If $success = Not True Then
MsgBox(0, "Not fund", "Line not found, so lets write")
_test()
EndIf
Func _test()
for $i = 0 to $file[0] Step 1
If StringInStr($file[$i], "cat") Then
_FileWriteToLine($myfile, $i+1,"dog",0)
EndIf
Next
EndFunc

It shouts this Error:

>"C:Program Files (x86)AutoIt3SciTE..autoit3.exe" /ErrorStdOut "C:UsersFabiDesktopelementstest.au3"

>Exit code: 0 Time: 0.785

And the test.txt hasn't change

[Melba23]

Sritra,

Your code works fine for me, but you have a major logical flaw within it. You are adding a line to the file when you write to it - that means that your line count for any subsequent _FileWriteToLine will be incorrect. If we start with this file:

cow
pig
cat
rat
fly

we get this aftet one replacement:

cow
pig
cat
dog
rat
fly

So you can see that all the subsequent lines are now pushed down one and so you will not write the next "dog" in the correct place.

You get over this by working up from the bottom of the list so that all the changes are below the current position in the file. I have rewritten the script to show this working:

#include <File.au3>

Global $fSuccess = False, $aLines

; This gets the file directly into an array - much faster than what you had before
$sMyFile = "test.txt"
_FileReadToArray($sMyFile, $aLines)

For $i = 0 To $aLines[0]
    If StringInStr($aLines[$i], "dog") Then
        $fSuccess = True
        ExitLoop
    EndIf
Next

If Not $fSuccess Then
    MsgBox(0, "Not found", "Line not found, so lets write")
    _test()
Else
    MsgBox(0, "Found", "OK")
EndIf

Func _test()
    For $i = $aLines[0] To 1 Step -1
        If StringInStr($aLines[$i], "cat") Then
            _FileWriteToLine($sMyFile, $i + 1, "dog", 0)

            ; This is just to show you what is happening as we move up the array
            $sFile = FileRead($sMyFile)
            MsgBox(0, "Current file content", $sFile)

        EndIf
    Next
EndFunc   ;==>_test

All clear? Please ask if not.

M23

[Sritra]

ok, I know my fault...

i changed the File.au3.....

[Melba23]

Sritra,

And what about the logic problem I highlighted? Will it be worth our responding to you in the future or will any help offered simply be ignored?

M23

[Sritra]

I thank You for that, but i just wanted to see, if my _FileWriteToLine() is working, the result was uneccesary, but thanks for trying to help me