Is there an easy way to do curved corners on Input controls?

[4Eyes 10]

As per the Topic Title... Is there an easy way to do curved corners on Input controls like the attached pic?

I'm thinking I might be able to use a graphic control with transparency that would have the outline and the 'outside' of the curves (sorry, hard to explain) draw in the colour of the background. The trouble with this is that it is not dynamic and doesn't cope with textured backgrounds.

Any clues?

Regards,

4Eyes

InputControlWithCurvedCorners.bmp

[GEOSoft 63]

I spend such little time in Example scripts anymore that I can't remember specifc scripts but that's the place to search for custom GUI scripts. Here are a couple to get you started.

http://www.autoitscript.com/forum/index.php?showtopic=102961&view=findpost&p=729998

http://www.autoitscript.com/forum/index.php?showtopic=106784&view=findpost&p=753514

[4Eyes 10]

George,

Thank you for your reply. Some interesting reading in there but I think I've come up with something that suits my purposes except for a textured background. I've tidied the graphic and attached here again. Change the surrounding colour to suit whatever GUI it goes into.

I must say I'm quite pleased!

Regards,

4Eyes

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $gui, $inpPassword, $pic

$gui = GUICreate("A", 450, 350, -1, -1)

$inpPassword = GUICtrlCreateInput("", 60, 100, 170, 20)
GUICtrlSetFont(-1, 10, 400, 0, "Arial")
GUICtrlSetState($inpPassword, $GUI_FOCUS)

$pic = GUICtrlCreatePic("InputControlWithCurvedCorners.bmp", 52, 95, 181, 30, "", $WS_EX_TRANSPARENT)

GUISetState()

; Loop until user exits
do
until GUIGetMsg() = $GUI_EVENT_CLOSE

InputControlWithCurvedCorners.bmp

[4Eyes 10]

Hmmm... obviously, not enough coffee. The above example works until you hover over the input control. I've spent most of today trying to fix it inc the hover UDF but nogo.

I'm not sure of the etiquette of whether I should bump my own thread or start another so please excuse my ignorance.

I have another question... can I change the colour of the outline (or bounding box if you like) of an input control?

The reason I ask this is that if I can then I could set it to the background colour of my gui and effectively it is invisible.

Ta,

4Eyes

[GEOSoft 63]

Beats me, I rarely try to skin out GUIs

[picea892 6]

use an edit instead

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $gui, $inpPassword, $pic

$gui = GUICreate("A", 450, 350, -1, -1)

$inpPassword = GUICtrlCreateedit("", 60, 100, 170, 20)
GUICtrlSetFont(-1, 10, 400, 0, "Arial")
GUICtrlSetState($inpPassword, $GUI_FOCUS)

$pic = GUICtrlCreatePic("InputControlWithCurvedCorners.bmp", 52, 95, 181, 30, "", $WS_EX_TRANSPARENT)

GUISetState()

; Loop until user exits
do
until GUIGetMsg() = $GUI_EVENT_CLOSE

[GEOSoft 63]

use an edit instead

That seems to have the same problem. As soon as you hover over it there is a problem.

[martin 66]

That seems to have the same problem. As soon as you hover over it there is a problem.

Here is a partial solution, by modifying one of Yashied's posts.

expandcollapse popup

#Include <GUIConstantsEx.au3>
#Include <WinAPI.au3>
#Include <WindowsConstants.au3>
#Include <GDIPlus.au3>

Global Const $sPng = 'editmask.png'

_GDIPlus_Startup()
$hImage = _GDIPlus_ImageLoadFromFile($sPng)

$hMain = GUICreate('Test', 250, 250, 400, 400)
GUISetBkColor(0xF0B7FD)
$Button = GUICtrlCreateButton('OK', 93, 216, 70, 23)
GUISetState()
GUICtrlCreateInput("",70,98,160,25)
$hPopup = GUICreate('', 199, 48 ,400+ 50,400+86, $WS_POPUP, $WS_EX_LAYERED)
GUISetState()
winsetontop($hPopup,"",1)
GUIRegisterMsg($WM_MOVE, "WM_MOVE")
winmove($hMain,"",401,400)

$Trans = 255

_SetBitmap($hPopup, $hImage, 255)
Do
 sleep(80)
Until GUIGetMsg() = -3

_GDIPlus_Shutdown()

Func _SetBitmap($hWnd, $hImage, $iOpacity)

    Local $hScrDC, $hMemDC, $hBitmap, $hOld, $pSize, $tSize, $pSource, $tSource, $pBlend, $tBlend

    $hScrDC = _WinAPI_GetDC(0)
    $hMemDC = _WinAPI_CreateCompatibleDC($hScrDC)
    $hBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
    $hOld = _WinAPI_SelectObject($hMemDC, $hBitmap)
    $tSize = DllStructCreate($tagSIZE)
    $pSize = DllStructGetPtr($tSize)
    DllStructSetData($tSize, 'X', _GDIPlus_ImageGetWidth($hImage))
    DllStructSetData($tSize, 'Y', _GDIPlus_ImageGetHeight($hImage))
    $tSource = DllStructCreate($tagPOINT)
    $pSource = DllStructGetPtr($tSource)
    $tBlend = DllStructCreate($tagBLENDFUNCTION)
    $pBlend = DllStructGetPtr($tBlend)
    DllStructSetData($tBlend, 'Alpha', $iOpacity)
    DllStructSetData($tBlend, 'Format', 1)
    _WinAPI_UpdateLayeredWindow($hWnd, $hScrDC, 0, $pSize, $hMemDC, $pSource, 0, $pBlend, $ULW_ALPHA)

    _WinAPI_ReleaseDC(0, $hScrDC)
    _WinAPI_SelectObject($hMemDC, $hOld)
    _WinAPI_DeleteObject($hBitmap)
    _WinAPI_DeleteDC($hMemDC)

EndFunc ;==>_SetBitmap

Func WM_MOVE($hWnd, $iMsg, $wParam, $lParam)
    Switch $hWnd
    Case $hMain
    WinMove($hPopup, '', BitAND($lParam, 0xFFFF) + 50, BitShift($lParam, 16) + 86)
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc ;==>WM_MOVE

[4Eyes 10]

martin,

Thank you. That works quite well.

The mask graphic you used gives me another idea too. I can make the colour of the 'outside of the input control the same as the gui to make it go away, or I can have a nice bezel in a different colour around the input control.

Great stuff.

Regards,

4Eyes