Drop file's and GUIOnEventMode enabled

[matthieuvb]

How to Drag and drop files with Opt("GUIOnEventMode", 1)?

@GUI_DragFile doesn't with option GUIOnEventMode.

is there another way to handle this?

thanks,

MatthieuAutoitScripter:)

[Melba23]

Matthieuautoitscripter,

@GUI_DragFile doesn't with option GUIOnEventMode

Nonsense, it works perfectly well:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Opt("GUIOnEventMode", 1)

$hGUI = GUICreate("Test", 500, 500, 100, 100, -1, $WS_EX_ACCEPTFILES)
GUISetOnEvent($GUI_EVENT_CLOSE, "On_Exit")

$hLabel = GUICtrlCreateLabel("", 0, 0, 500, 500)
GUICtrlSetState(-1, $GUI_DROPACCEPTED)

GUISetOnEvent($GUI_EVENT_DROPPED, "On_Drop")

GUISetState()

While 1
    Sleep(10)
WEnd

Func On_Drop()
    MsgBox(0, "", @GUI_DragFile)
EndFunc

Func On_Exit()
    Exit
EndFunc

It even tells you the 2 work together in the Help file:

@GUI_DragFile - Filename of the file being dropped. Only valid on Drop Event. See the GUISetOnEvent function.

And just in case anyone thinks that it is limited to OnEvent mode only, here it is working in MessageLoop mode:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$hGUI = GUICreate("Test", 500, 500, 100, 100, -1, $WS_EX_ACCEPTFILES)

$hLabel = GUICtrlCreateLabel("", 0, 0, 500, 500)
GUICtrlSetState(-1, $GUI_DROPACCEPTED)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_DROPPED
            MsgBox(0, "", @GUI_DragFile)
    EndSwitch
WEnd

M23

[matthieuvb]

thanks, it works! great!