Date picker

[Gogi02]

First of all sorry for my not so perfect english. What I'd like to do is program a date picker where user is presented with a box where he can enter numbers and function automatically converts it to date format. For example user would enter 01072010 and program would convert it to date format like 01.07.2010. Unfortunately I have no Idea how to do it. Could someone please point me in the right direction?

[Mat]

We've got better than that... Built in (sort of)

#include <GuiDateTimePicker.au3>

; Create GUI
Local $hGUI = GUICreate("DateTimePick", 400, 300)
Local $hDTP = _GUICtrlDTP_Create($hGUI, 2, 6, 190)
GUISetState()

; Set the display format
_GUICtrlDTP_SetFormat($hDTP, "dd:MM:yyyy")

; Loop until user exits
While GUIGetMsg() <> -3
    Sleep(10)
WEnd

Edit: changed format to what OP wanted

Edited June 30, 2010 by Mat

[Gogi02]

Yeah I know about that. But I'd like to modify that so that when you enter day it would automatically jump to months and then years without the need to press an arrow key.

[Mat]

You might need to process the $DTN_USERSTRING notification... I'll have a look at it for you as I'm surprised it doesn't do it by default...

[Gogi02]

On the other note. How do I get data from picker box. What I mean is how do I get the date picked in a variable so I can work with it?

[Mat]

_GUICtrlDTP_GetSystemTime

[tivp]

Dear @Gogi02, it may be that my code is very helpful for what you are looking for. 🤔





Seleccionar Fecha y Hora.au3

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiDateTimePicker.au3>
#include <DateTimeConstants.au3>
#include <MsgBoxConstants.au3>

; Activar declaración obligatoria de variables para evitar errores de ejecución.
Opt("MustDeclareVars", 1)

; Referencias de controles GUI.
Global $idDate, $idTime, $hTime, $btnAceptar

; Parámetros de diseño.
Global $iTimeWidth = 220
Global $iMargin = 10
Global $iButtonWidth = 100
Global $iWinHeight = 130

; Dimensiones calculadas de la ventana.
Local $iWinWidth = $iTimeWidth + (2 * $iMargin)
Local $iButtonCenteredX = ($iWinWidth - $iButtonWidth) / 2

; Creación de la ventana principal.
GUICreate("Seleccionar Fecha y Hora", $iWinWidth, $iWinHeight)

; Control de selección de fecha.
$idDate = GUICtrlCreateDate("", $iMargin, 10, $iTimeWidth, 22)
_GUICtrlDTP_SetFormat(GUICtrlGetHandle($idDate), "dd'/'MM'/'yyyy")

; Control de selección de hora con ajuste manual.
Local $iTimeStyle = BitOR($DTS_TIMEFORMAT, $DTS_UPDOWN)
$idTime = GUICtrlCreateDate("", $iMargin, 44, $iTimeWidth, 22, $iTimeStyle)
$hTime = GUICtrlGetHandle($idTime)
_GUICtrlDTP_SetFormat($hTime, "HH:mm")

; Inicialización del selector con la hora actual.
Local $aNow[7] = [False, @YEAR, @MON, @MDAY, @HOUR, @MIN, 0]
_GUICtrlDTP_SetSystemTime($hTime, $aNow)

; Botón de confirmación.
$btnAceptar = GUICtrlCreateButton("Aceptar", $iButtonCenteredX, 82, $iButtonWidth, 30)

; Mostrar interfaz.
GUISetState(@SW_SHOW)

; Gestión de eventos.
While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit

        Case $btnAceptar
            Local $sFecha = GUICtrlRead($idDate)
            Local $sHora  = GUICtrlRead($idTime)
            MsgBox($MB_ICONINFORMATION, "Resultado", "Fecha: " & $sFecha & @CRLF & "Hora: " & $sHora)
    EndSwitch
WEnd

Edited December 8 by tivp
Fix some bugs