For Loop Logic Help

[LurchMan]

Hey Everyone -

I've got the following code:

For $n = 0 To UBound($aData) - 1 Step $aCols[0]
     _GUICtrlListView_AddItem($ListView1, $aData[$n], $iCnt) ;Create first row
     For $i = $n To $aCols[0] ;Suppose to add remaining elements in row
         _GUICtrlListView_AddSubItem($ListView1, $iCnt, $aData[$i], $i) 
     Next
     $iCnt += 1
Next

Basically The Array $aData Contains info pulled from a Database, $aCols[0] Contains how many columns is in the database. I know this probably isn't explained the best but the problem I'm having is getting the remaining elements from the Array into the correct row. If I need to explain further please let me know. If there is a better way to do this, or if there is something wrong with the way I'm doing it please correct me. I end up getting The first remaining element in the right spot but after that the columns are just blank.

[Melba23]

LurchMan,

The error was in the inner loop - see if you can spot the difference:

#include <GUIConstantsEx.au3>
#Include <GuiListView.au3>

Global $aCols[1] =[5]

Global $aData[10] = [0, 1, 2, 3, 4, 10, 11, 12, 13, 14]

$hGUI = GUICreate("Test", 500, 500)

$ListView1 = _GUICtrlListView_Create($hGUI, "Zero|One|Two|Three|Four", 10, 10, 480, 380)

GUISetState()

$iCount = 0

For $n = 0 To UBound($aData) - 1 Step $aCols[0]
    _GUICtrlListView_AddItem($ListView1, $aData[$n], $iCount) ;Create first row
    For $i = 0 To $aCols[0] - 1 ;Add remaining elements in row
        _GUICtrlListView_AddSubItem($ListView1, $iCount, $aData[$n + $i], $i)
    Next
    $iCount += 1
Next

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

M23

[LurchMan]

LurchMan,

The error was in the inner loop - see if you can spot the difference:

#include <GUIConstantsEx.au3>
#Include <GuiListView.au3>

Global $aCols[1] =[5]

Global $aData[10] = [0, 1, 2, 3, 4, 10, 11, 12, 13, 14]

$hGUI = GUICreate("Test", 500, 500)

$ListView1 = _GUICtrlListView_Create($hGUI, "Zero|One|Two|Three|Four", 10, 10, 480, 380)

GUISetState()

$iCount = 0

For $n = 0 To UBound($aData) - 1 Step $aCols[0]
    _GUICtrlListView_AddItem($ListView1, $aData[$n], $iCount) ;Create first row
    For $i = 0 To $aCols[0] - 1 ;Add remaining elements in row
        _GUICtrlListView_AddSubItem($ListView1, $iCount, $aData[$n + $i], $i)
    Next
    $iCount += 1
Next

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

M23

Thank you so much Melba! I've been beatin my head against the wall for 2 days trying to figure it out and it took you 10 mins lol..again, thank you for your help!