Check if macro is declared

[SublimePorte]

I want to know whether a function is called by GUICtrlSetOnEvent or not. Is there a way to check if @GUI_CTRLID is set?

[MvGulik]

To your direct question. No.

Don't know what it is you coding. But you seem to make things more complicated than you should. (unless your just experimenting.)

Edited August 3, 2010 by MvGulik

[picaxe]

  Quote

I want to know whether a function is called by GUICtrlSetOnEvent or not.

One way

;Opt("GUIOnEventMode", 1)

If _IsOnEvent() Then
    $sState = "On"
Else
    $sState = "Off"
EndIf
ConsoleWrite("Event Mode is " & $sState & @LF)

Func _IsOnEvent()
    $iOnEvent = Opt("GUIOnEventMode", 1)
    Opt("GUIOnEventMode", $iOnEvent)
    Return $iOnEvent
EndFunc

[SublimePorte]

  Quote

Don't know what it is you coding. But you seem to make things more complicated than you should. (unless your just experimenting.)

It's a setup tool for a fairly complicated series of steps that need to be done to run a certain testing suite. I am not experimenting, been using AutoIt for about 3 or 4 years now.

I just need to reuse some functions which are quite a decent size, so being able to call them by GuiCtrlSetOnEvent or not, is a must. I don't see why you consider it to be so complicated?

[Melba23]

SublimePorte,

Perhaps you could use a wrapper function to set a flag when you call your function via OnEvent - something like this:

expandcollapse popup

#include <GUIConstantsEx.au3>

Opt("GUIOnEventMode", 1)

$fOnEvent = False

$hGUI = GUICreate("Test", 500, 500)
GUISetOnEvent($GUI_EVENT_CLOSE, "On_Exit")

$hButton_1 = GUICtrlCreateButton("Test", 10, 10, 80, 30)
GUICtrlSetOnEvent(-1, "Wrapper") ; You really want to call Function here, but go via Wrapper

$hButton_2 = GUICtrlCreateButton("Test", 10, 50, 80, 30)
GUICtrlSetOnEvent(-1, "Wrapper")

GUISetState()

AdlibRegister("Function", 2000)

While 1
    Sleep(10)
WEnd

Func Function() ; This is the function you wanted to call

    If $fOnEvent Then
        ConsoleWrite("I was called via OnEvent from " & @GUI_CtrlId & @CRLF)
    Else
        ConsoleWrite("I was NOT called via OnEvent" & @CRLF)
    EndIf
    $fOnEvent = False

EndFunc

Func Wrapper() ; This is the function you actually call

    $fOnEvent = True
    Function()

EndFunc

Func On_Exit()

    Exit

EndFunc

Any use?

M23