Input from one control to next without tabbing

[caravelman]

I have two input controls, first with max 2 characters and second with max 5 characters, as soon as user enters two characters in first input control, I want to move him to next Input control without him hitting the tab, How can I do that ?

Your help is appreciated.

My Code:

$caseyear = GUICtrlCreateInput("", 224, 128, 73, 32, $ES_NUMBER)

GUICtrlSetLimit($caseyear, 2)

$Label3 = GUICtrlCreateLabel("-", 304, 128, 10, 28)

$casenum = GUICtrlCreateInput("", 320, 128, 145, 32, $ES_NUMBER)

GUICtrlSetLimit($casenum, 5)

I want to move to $casenum after I enter two digit for year without hitting TAB key.

[Melba23]

caravelman,

Welcome to the AutoIt forum.

You can do what you want like this:

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)

$hInput_1 = GUICtrlCreateInput("", 10, 10, 200, 20)
; Set limit for top input
GUICtrlSetLimit(-1, 2)

$hInput_2 = GUICtrlCreateInput("", 10, 50, 200, 20)
; Set limit for bottom input
GUICtrlSetLimit(-1, 5)

GUISetState()

; Set focus to top input
GUICtrlSetState($hInput_1, $GUI_FOCUS)

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    ; If bottom input is empty
    If GUICtrlRead($hInput_2) = "" Then
        ; And top input is full
        If StringLen(GUICtrlRead($hInput_1)) = 2 Then
            ; Set focus to bottom input
            GUICtrlSetState($hInput_2, $GUI_FOCUS)
        EndIf
    EndIf

WEnd

Note that we need 2 checks to decide when we need to set focus to the bottom input - if you remove the outer If statement, it does not work as you want. Try it and see!

Please ask if you have any questions.

M23

P.S. If you want a more complicated example - you can look here!

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $iInput_Limit = 2

$hGUI = GUICreate("Demo", 200, 100)

$hInput_1 = GUICtrlCreateInput("", 20, 20, 30, 20)
GUICtrlSetLimit(-1, $iInput_Limit)
$hInput_2 = GUICtrlCreateInput("", 80, 20, 30, 20)
GUICtrlSetLimit(-1, $iInput_Limit)
$hInput_3 = GUICtrlCreateInput("", 140, 20, 30, 20)
GUICtrlSetLimit(-1, $iInput_Limit)

$hButton = GUICtrlCreateButton("OK", 60, 60, 80, 30)
GUICtrlSetState(-1, $GUI_DISABLE)

GUIRegisterMsg($WM_COMMAND, "On_WM_COMMAND") ; 0x0111

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hButton
            $sResult = GUICtrlRead($hInput_1) & "-" & GUICtrlRead($hInput_2) & "-" & GUICtrlRead($hInput_3)
            MsgBox(0, "You have entered", $sResult)
    EndSwitch

    ; Enable button when last input filled
    If StringLen(GUICtrlRead($hInput_3)) = 2 And BitAnd(GUICtrlGetState($hButton), $GUI_DISABLE) = $GUI_DISABLE Then GUICtrlSetState($hButton, $GUI_ENABLE)

WEnd

Func On_WM_COMMAND($hWnd, $Msg, $wParam, $lParam)

    $nNotifyCode = BitShift($wParam, 16)
    $iControlID = BitAnd($wParam, 0x0000FFFF)
    ; If input filled move focus to next
    Switch $nNotifyCode
        Case 0x400 ;$EN_UPDATE
            If StringLen(GUICtrlRead($iControlID)) = $iInput_Limit Then GUICtrlSetState($iControlID + 1, $GUI_FOCUS)
    EndSwitch

EndFunc

[caravelman]

Thank you M23. You have been great help.

Caravelman