GUICtrlCreateCombo SetLimit ?

[Merchants 0]

how to set a limit?

like

$GUI = GuiCtrlCreateInput("10 chars max!", 213, 45, 32, 20)

GUICtrlSetLimit($GUI, 10)

but then in a combo box

$GUI = GUICtrlCreateCombo("10 chars max!", 141, 22, 104, 20)

GUICtrlSetLimit($GUI, 10) ??

Edited November 2, 2010 by Merchants

[GEOSoft 68]

GUICtrlSetLimit() Can be used for Up/Down, slider, edit, input and list controls but I don't think it has any effect on a combobox.

[PsaltyDS 41]

A ComboBox only presents choices presented by the application in the control, so limits don't make sense there. But you can have an Edit control (input) subclassed on to the ComboBox and maybe you could apply it to that. I haven't tried it, but you might get the handle to the edit with _GUICtrlComboBoxEx_GetEditControl() and set a limit on that.

[BrewManNH 1,306]

The contents of a combo box are set by the programmer, don't use more characters than you want displayed in your combo box and you won't need to try and set a limit. A user can type in a combo box, but if you only check for the contents that you put into it, then that shouldn't be an issue.

[Melba23 3,489]

Merchants,

Here is one way to do it:

#include <GUIConstantsEx.au3>
#Include <GuiComboBox.au3>

$hGUI = GUICreate("Test", 500, 500)

$hCombo = GUICtrlCreateCombo("", 10, 10, 200, 20)
GUICtrlSetData($hCombo, "Option1|Option2")

$hComboDummy = GUICtrlCreateDummy()

GUISetState()

Global $AccelKeys[1][2]=[["{ENTER}", $hComboDummy]]
GUISetAccelerators($AccelKeys)

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hComboDummy
            ContinueCase
        Case $hCombo
            ConsoleWrite(GUICtrlRead($hCombo) & @CRLF)
    EndSwitch

    $sText = GUICtrlRead($hCombo)
    If StringLen($sText) > 10 Then
        $sText = StringMid($sText, 1, 10)
        _GUICtrlComboBox_SetEditText($hCombo, $sText)
    EndIf

WEnd

There are probably sexier ways to do it by getting the handle of the edit control and and looking for $EN_CHANGE messages, but this works for me!

M23

[PsaltyDS 41]

This was what I meant, and you don't have to monitor it at all:

#include <GuiConstantsEx.au3>
#include <GuiEdit.au3>
#include <GuiComboBoxEx.au3>

Global $hGUI, $hCombo, $hEdit

; Create GUI
$hGUI = GUICreate("ComboBoxEx Get Edit Control", 400, 300)
$hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 268)
For $x = 0 To 5
    _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Random string", Random(1, 100, 1)))
Next
$hEdit = _GUICtrlComboBoxEx_GetEditControl($hCombo)
_GUICtrlEdit_SetLimitText($hEdit, 16)
GUISetState()

; Loop until user exits
MsgBox(64, "Limit", "ComboBox Edit control limit = " & _GUICtrlEdit_GetLimitText($hEdit))
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

[Melba23 3,489]

Just for completeness, here is a way to limit the number of characters using the Windows message as I mentioned above:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Include <GuiComboBox.au3>

$hGUI = GUICreate("Test", 500, 500)

$hCombo = GUICtrlCreateCombo("", 10, 10, 200, 20)
$hCombo_Handle = GUICtrlGetHandle($hCombo)
GUICtrlSetData($hCombo, "Option 1|Option 2")

GUISetState()

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

WEnd

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)

    #forceref $hWnd, $iMsg
    Local $hWndFrom = $lParam
    Local $iCode = BitShift($wParam, 16) ; Hi Word
    Switch $hWndFrom
        Case $hCombo_Handle
            Switch $iCode
                Case $CBN_EDITCHANGE ; Sent after the user has altered the text in the edit control portion of a combo box
                    $sText = GUICtrlRead($hCombo)
                    If StringLen($sText) > 10 Then
                        $sText = StringMid($sText, 1, 10)
                        _GUICtrlComboBox_SetEditText($hCombo, $sText)
                    EndIf
            EndSwitch
    EndSwitch

    Return $GUI_RUNDEFMSG

EndFunc

M23