Simple text placment on desktop without boarders

[PeterAtkin]

I'm looking for a way to have just some text 'Version Number' to be discreetly displayed without boarder and preferably overlayed so as not to disturb the background/desktop showing while the compiled script is running.

I've had a look to see if these anything I could use but either I'm just not looking right or this is harder than it looks.

Any pointers would be appreciated

Edited November 7, 2010 by PeterAtkin

[hessebou]

maybe this example is usefull for you:

expandcollapse popup

#include <StaticConstants.au3>
#include <EditConstants.au3>
#include <ComboConstants.au3>
#include <GuiConstants.au3>
#include <WindowsConstants.au3>
#include <ButtonConstants.au3>
#Include <Misc.au3>
#include <Constants.au3>
#Include <GuiButton.au3>
#include <GDIPlus.au3>
_GDIPlus_Startup()
$kPen = _GDIPlus_BrushCreateSolid()
$hFamily = _GDIPlus_FontFamilyCreate ("Arial")
$hFont = _GDIPlus_FontCreate ($hFamily, 12, 2)
$hFormat = _GDIPlus_StringFormatCreate ()
_GDIPlus_StringFormatSetAlign($hFormat, 1)
Opt("GuiOnEventMode", 1)
GUICreate("temptext", 100, 25, @DesktopWidth/2, @DesktopHeight/2, BitOR($WS_POPUP,$WS_CLIPCHILDREN), $WS_EX_LAYERED+$WS_EX_TOPMOST)
GUISetBkColor(0x010101)
GUISetState()
$xys = WinGetHandle ("[ACTIVE]")
_WinAPI_SetLayeredWindowAttributes($xys, 0x010101)
$tGraphic = _GDIPlus_GraphicsCreateFromHWND($xys)
$ttLayout = _GDIPlus_RectFCreate (0, 0, 100, 25)
_GDIPlus_GraphicsDrawStringEx ($tGraphic, "Version 1.0", $hFont, $ttLayout, $hFormat, $kPen)
GUISetOnEvent($GUI_EVENT_PRIMARYDOWN, "SystemEvents")
GUISetOnEvent($GUI_EVENT_SECONDARYDOWN, "SystemEvents")
While 1
    Sleep(10)
WEnd
Func SystemEvents()
    Switch @GUI_CtrlId
        Case $GUI_EVENT_PRIMARYDOWN
            DllCall("user32.dll","int","SendMessage","hWnd", $xys,"int",$WM_NCLBUTTONDOWN,"int", $HTCAPTION,"int", 0)
        Case $GUI_EVENT_SECONDARYDOWN
            exit
    EndSwitch
EndFunc

[PeterAtkin]

Wow thanks, and as expected much more complex than i had anticipated, this looks like it will do the trick..

Edited November 8, 2010 by PeterAtkin

[GEOSoft]

You might also be interested in this one by Valuater

[UEZ]

Here an example from help file (GUICtrlCreateProgress ()) modified:

expandcollapse popup

#include <Constants.au3>
#include <WinAPI.au3>
#include <GuiEdit.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <ProgressConstants.au3>

Opt('MustDeclareVars', 1)

Example()

Func Example()
    Local $progressbar1, $progressbar2, $button, $wait, $s, $msg, $m, $hGUI

    $hGUI = GUICreate("My GUI Progressbar", 220, 100, -1, -1, Default, $WS_EX_TOPMOST)
    $progressbar1 = GUICtrlCreateProgress(10, 10, 200, 20)
    GUICtrlSetColor(-1, 32250); not working with Windows XP Style
    $progressbar2 = GUICtrlCreateProgress(10, 40, 200, 20, $PBS_SMOOTH)
    $button = GUICtrlCreateButton("Start", 75, 70, 70, 20)
    GUISetState(@SW_SHOW, $hGUI)

    #region additional
    Local $hGUI_Transparent, $label
    $hGUI_Transparent = GUICreate("Test", 100, 50, @DesktopWidth - 100, @DesktopHeight - 80, $WS_POPUP, BitOR($WS_EX_TOOLWINDOW, $WS_EX_LAYERED, $WS_EX_TOPMOST))
    GUISetBkColor(0x00, $hGUI_Transparent)
    $label = GUICtrlCreateLabel("v1.0.0.1", 0, 0, 100, 50)
    GUICtrlSetColor(-1, 0x0000A0)
    GUICtrlSetFont(-1, 16, 800)
    _WinAPI_SetLayeredWindowAttributes($hGUI_Transparent, 0x00, 255, 1, False)
    GUISetState(@SW_SHOW, $hGUI_Transparent)
    #endregion

    $wait = 20; wait 20ms for next progressstep
    $s = 0; progressbar-saveposition
    Do
        $msg = GUIGetMsg()
        If $msg = $button Then
            GUICtrlSetData($button, "Stop")
            For $i = $s To 100
                If GUICtrlRead($progressbar1) = 50 Then MsgBox(0, "Info", "The half is done...", 1)
                $m = GUIGetMsg()

                If $m = -3 Then ExitLoop

                If $m = $button Then
                    GUICtrlSetData($button, "Next")
                    $s = $i;save the current bar-position to $s
                    ExitLoop
                Else
                    $s = 0
                    GUICtrlSetData($progressbar1, $i)
                    GUICtrlSetData($progressbar2, (100 - $i))
                    Sleep($wait)
                EndIf
            Next
            If $i > 100 Then
                ;       $s=0
                GUICtrlSetData($button, "Start")
            EndIf
        EndIf
    Until $msg = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

The additional code is within the region

Br,

UEZ

Edited November 8, 2010 by UEZ

[ViRnik]

Im sorry for necro this thread but i got a question about this text.

How to make this text to appear on screen when im running full window program/game? I cant find a solution, maybe someone can give me direction where to look at?

Thanks

[ViRnik]

sorry for double post.

I did transparent text with layered window, workin great, I can keep it on top in FULL window game/program with ShiftWindow program. It doesnt solve my issue completly coz i wanted to do it with autoit only, If anyone know how to do it let me know.

Link to shiftwindow: http://www.grismar.net/shiftwindow/