_SendMessage Failing

[Skrip]

In two seperate scripts,

Run this:

#include <GUIConstantsEx.au3>
#include <EditConstants.au3>
#include <SendMessage.au3>
$hGUI = GUICreate("Test", 500, 50)
$hEdit = GUICtrlCreateInput("TEST", 10, 10, 400, 20, $ES_PASSWORD)
GUISetState()

;~ ConsoleWrite(_SendMessage(GUICtrlGetHandle($hEdit), $EM_SETPASSWORDCHAR, 0, 0))
Do
    Sleep(100)
Until GUIGetMsg() = -3

Then this:

ConsoleWrite(ControlGetHandle("Test", "", "[CLASS:Edit]") & @CRLF)
If _SendMessage(ControlGetHandle("Test", "", "[CLASS:Edit]"), $EM_SETPASSWORDCHAR, 0) = @error Then ConsoleWriteError("The saddening error was: " & @error)

Why does _SendMessage fail? Is this a security feature of an input box or what is the issue?

Edited November 8, 2010 by Skrip

[PsaltyDS]

I suspect you are simply not allowed to have one process screw around with that parameter in another process' GUI (with default permissions, any way). It works fine within the same script:

#include <GUIConstantsEx.au3>
#include <EditConstants.au3>
#include <SendMessage.au3>

$iPWChar = 0
$hGUI = GUICreate("Test", 500, 110)
$idEdit = GUICtrlCreateInput("TEST", 20, 20, 460, 20, $ES_PASSWORD)
$hEdit = GUICtrlGetHandle(-1)
$idButton = GUICtrlCreateButton("CHANGE", 200, 60, 100, 30)
GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $idButton
            If $iPWChar Then
                $iPWChar = 0
            Else
                $iPWChar = 35 ; # char
            EndIf
            ConsoleWrite("$hEdit = " & $hEdit & "; $iPWChar = " & $iPWChar & @CRLF)
            $iRet = _SendMessage($hEdit, $EM_SETPASSWORDCHAR, $iPWChar)
            $iErrSav = @error
            ControlFocus($hGUI, "", $hEdit)
            ConsoleWrite("$iRet = " & $iRet & "; $iErrSav = " & $iErrSav & @LF)
    EndSwitch
WEnd

[GEOSoft]

If _SendMessage(ControlGetHandle("Test", "", "[CLASS:Edit]"), $EM_SETPASSWORDCHAR, 0) = @error Then ConsoleWriteError("The saddening error was: " & @error)

is horrible usage of that function call coupled with error checking. The odds of the return from _SendMessage() equaling the error level are pretty slim I think so you should be doing error checking separately.

[Skrip]

If _SendMessage(ControlGetHandle("Test", "", "[CLASS:Edit]"), $EM_SETPASSWORDCHAR, 0) = @error Then ConsoleWriteError("The saddening error was: " & @error)

is horrible usage of that function call coupled with error checking. The odds of the return from _SendMessage() equaling the error level are pretty slim I think so you should be doing error checking separately.

I know. I just threw it together because it was after midnight and I was trying to get to bed.

I understand the issue though.