Problem With Embedded IE & Variables...

[supadodger]

For $x = 1 To 10
    Dim $oIE[1000]
    Dim $GuiActiveX[1000]
    $oIE[$x] = ObjCreate("Shell.Explorer.2")
    GUICreate("Brandons Browser", 1024, 960, 1, 1)
    $GuiActiveX[$x] = GUICtrlCreateObj($oIE[$x], 1, 1, 1024, 960)
    GuiSetState()
Next


            For $z = 1 To 10
                $oIE[$z].Navigate("http://www.google.com")
            Next
For $z = 1 To 10
_IeLoadWait($oie[$z])
            Next

$oIE[$z].Navigate("http://www.google.com")

$oIE[$z]^ ERROR

am i missing something simple?

[iamtheky]

Dont know that the object return needs to iterate, also couldnt tell what you are quite after, heres a guess.

#include <IE.au3>
#include <Array.au3>


    Dim $GuiActiveX[4]

for $x = 1 to 3
    $oIE = ObjCreate("Shell.Explorer.2")
    GUICreate("Brandons Browser", 1024, 960, 1, 1 )
    Guisetstate ()
    $GuiActiveX[$x] = GUICtrlCreateObj($oIE, 1, 1, 1024, 960)
    $oIE.Navigate("http://www.google.com")

next

_arraydisplay ($GuiActiveX)


while 1
    guisetstate()
    wend

Edited November 18, 2010 by iamtheky

[PsaltyDS]

$oIE[$z].Navigate("http://www.google.com")

$oIE[$z]^ ERROR

am i missing something simple?

Just AutoIt syntax. You can't use an array reference directly as an object like that. Try this instead:

#include <IE.au3>

Global $aIE[10]

For $x = 0 To UBound($aIE) - 1
    $aIE[$x] = ObjCreate("Shell.Explorer.2")
    GUICreate("Brandons Browser", 800, 600, $x * 20, $x * 20)
    GUICtrlCreateObj($aIE[$x], 5, 5, 790, 590)
    GUISetState()
Next

For $oIE In $aIE
    $oIE.Navigate("http://www.google.com")
Next

For $oIE In $aIE
    _IELoadWait($oIE)
Next

MsgBox(64, "Done", "Done")

Another way to look at it would be:

For $z = 1 To 10
     $oTemp = $oIE[$z]
     $oTemp.Navigate("http://www.google.com")
Next

Edited November 18, 2010 by PsaltyDS

[supadodger]

#include <ie.au3>
Dim $oIE[1000]
Dim $GuiActiveX[1000]
For $x = 1 To 10
    $oIE[$x] = ObjCreate("Shell.Explorer.2")
    GUICreate("Brandons Browser", 1024, 960, 1, 1)
    $GuiActiveX[$x] = GUICtrlCreateObj($oIE[$x], 1, 1, 1024, 960)
    GUISetState()
Next


For $z = 1 To 10
    $oTemp = $oIE[$z]
    $oTemp.Navigate("http://www.google.com")
Next
For $z = 1 To 10
    _IELoadWait($oIE[$z])
Next

working great

Edited November 18, 2010 by supadodger