Bkground Transparent

[Vision]

hello!

im trying to make my gui transparent but i want just the background transparent not the controls so Winsettrans will not work in my way.

i found in the help files _WinAPI_SetLayeredWindowAttributes but it has no effect in my script, in the example it works good anyone knows why?

here is my "test" script

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <ButtonConstants.au3>
#include <StaticConstants.au3>
#include <WINAPI.au3>
#include <WindowsConstants.au3>
#include <GuiButton.au3>
#include <GuiImageList.au3>
Global $Cursor1, $Button1

$gui = GUICreate("Test", 300, 200, -1, -1)

GUISetStyle($WS_POPUP, -1, $gui)   ; NO BORDERS

$label = GUICtrlCreateButton("test", 30, 50, 50, 120, $BS_BITMAP)
$cursor = GUIGetCursorInfo()

_WinAPI_SetLayeredWindowAttributes($gui, 0xABCDEF,255)  ; <-- Why this dont make the window transparent?

GUISetState()
AdlibRegister("_Hover_Label")

Func _Hover_Label()
    $pos = GUIGetCursorInfo()
    If $pos[4] = $label Then
        _GUICtrlButton_SetSize($label, 50, 120)
    Else
        _GUICtrlButton_SetSize($label, 20, 100)
    EndIf
EndFunc

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
    EndSwitch
WEnd

[Melba23]

Vision,

Firstly you need to set the $WS_EX_LAYERED extended style.

Secondly, you need to set the GUI background to the colour you later make transparent.

So you end up with this (look for the <<<<<<<<< lines):

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <ButtonConstants.au3>
#include <StaticConstants.au3>
#include <WINAPI.au3>
#include <WindowsConstants.au3>
#include <GuiButton.au3>
#include <GuiImageList.au3>
Global $Cursor1, $Button1

$gui = GUICreate("Test", 300, 200, -1, -1)
GUISetBkColor(0xABCDEF) ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<

GUISetStyle($WS_POPUP, $WS_EX_LAYERED, $gui)   ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<

$label = GUICtrlCreateButton("test", 30, 50, 50, 120, $BS_BITMAP)
$cursor = GUIGetCursorInfo()

_WinAPI_SetLayeredWindowAttributes($gui, 0xABCDEF,255)  ; <-- It does now! <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<

GUISetState()
AdlibRegister("_Hover_Label")

Func _Hover_Label()
    $pos = GUIGetCursorInfo()
    If $pos[4] = $label Then
        _GUICtrlButton_SetSize($label, 50, 120)
    Else
        _GUICtrlButton_SetSize($label, 20, 100)
    EndIf
EndFunc

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
    EndSwitch
WEnd

All clear?

M23

[Vision]

perfect!

thanks much

(would be good if this "trick" would be in the help file^^)

one additional mini question

can yo give me a tip how i can fix that the program crashes when i click something outside the program?

the array returned from GUIGetCursorInfo() does a critical ERROR

Edited December 22, 2010 by Vision

[smashly]

Hi,

Func _Hover_Label()
    $pos = GUIGetCursorInfo()
    If IsArray($pos) And $pos[4] = $label Then
        _GUICtrlButton_SetSize($label, 50, 120)
    Else
        _GUICtrlButton_SetSize($label, 20, 100)
    EndIf
EndFunc

Cheers

[JoHanatCent]

can yo give me a tip how i can fix that the program crashes when i click something outside the program?

the array returned from GUIGetCursorInfo() does a critical ERROR

WinGetPos($GUI)

or else just use

_MouseTrap