Problems installing Autoit

[oMBRa]

I have recently installed Windows 7 Ultimate 32 bit, today I have installed the latest version of Autoit and all went fine (I used the installer).

Then I have tried to create a new script (as I was used to do), Right-Click on desktop--->New--->??, the "New Autoit" voice was missing, so I have created an au3 file on desktop manually and the extension wasn't even associated with SciTE.

I have already tried installing Autoit running the installer in compatibilty mode for Windows XP SP2 & SP3.

Thanks in advance

[Zedna]

Download/Install also Scite4Autoit3.

[oMBRa]

Yes, I have already done it

[Jos]

When you install SciTE4AutoIt3 you will get the choice to associate Open with Edit to open the script in SciTE on DoubleClick (Open).

Did you change that from Run to Edit?

Jos

Try running the below script to fix any settings you might have done which have overridden the Default settings:

expandcollapse popup

; Scriptname: FixHelpFileExamples.au3
; Script to fix Registry setting for SciTE/AutoIt3/Helpfile Open Button
;
If Not FileExists(@ScriptDir & '\Autoit3.exe') then
    MsgBox(16,"Autoit3.exe error",'File Autoit3.exe not found. Place this script in the AutoIt3 program directory and run it again.')
    Exit
EndIf
If Not FileExists(@ScriptDir & '\SciTE\SciTE.exe') then
    MsgBox(16,"SciTE.exe error",'File ..\SciTE\SciTE.exe not found. Something is not installer the standard way. Exiting.')
    Exit
EndIf
$Open_SciTe = '"' & @ScriptDir & '\SciTE\SciTE.exe" "%1"'
$Edit_SciTe = '"' & @ScriptDir & '\SciTE\SciTE.exe" "%1"'
$Run_SciTe = '"' & @ScriptDir & '\AutoIt3.exe" "%1" %*'
$Open = RegRead("HKCR\AutoIt3Script\Shell\Open\Command", "")
$Edit = RegRead("HKCR\AutoIt3Script\Shell\Edit\Command", "")
$Run = RegRead("HKCR\AutoIt3Script\Shell\Run\Command", "")
$Default = RegRead("HKCR\AutoIt3Script\Shell", "")
$FixedOpen = RegRead("HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.au3", "Application")
ConsoleWrite("+****************************************************************************************" &@CRLF)
ConsoleWrite("+* Current setting: " &@CRLF)
ConsoleWrite("+*        Default action:" & $Default & @CRLF)
ConsoleWrite("+*                   Run:" & $Run & @CRLF)
ConsoleWrite("+*                  Open:" & $Open & @CRLF)
ConsoleWrite("+*                  Edit:" & $Edit & @CRLF)
ConsoleWrite("+*      Always open with:" & $FixedOpen & @CRLF)
ConsoleWrite("+****************************************************************************************" &@CRLF)
; Check for "Always open with settings
If $FixedOpen <> "" Then
    If MsgBox(4, "Override setting for Open on .AU3", 'You have specified to "Always Open" with:' & @CRLF & $FixedOpen & _
            @CRLF & " But this should be removed and the standard setting should be used!" & _
            @CRLF & @CRLF & "Click Yes to Remove this Keys") = 6 Then
        $rc = RegDelete("HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.au3", "Application")
        ConsoleWrite('-RegDelete ("HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.au3", "Application") $rc = ' & $rc & "  @Error=" & @error & @CRLF)
    Else
        ConsoleWrite('! Override setting for Open on .AU3 not removed' & @CRLF)
    EndIf
Else
    ConsoleWrite('+No Open override on .au3.' & @CRLF)
EndIf
; Check Edit Settings
If $Edit <> $Edit_SciTe Then
    If MsgBox(4, "Edit Settings for AU3", 'Your "Edit" settings are currently:' & @CRLF & $Edit & @CRLF & " But should be:" & @CRLF & $Edit_SciTe & @CRLF & @CRLF & " Update?") = 6 Then
        $rc = RegWrite("HKCR\AutoIt3Script\Shell\Edit\Command", "", "REG_SZ", $Edit_SciTe)
        ConsoleWrite('-RegWrite Edit $rc = ' & $rc & "  @Error=" & @error & @CRLF)
    EndIf
Else
    ConsoleWrite('+Edit already set to default = ' & $Edit & @CRLF)
EndIf
; Check Open Settings
If $Open <> $Open_SciTe Then
    If MsgBox(4, "Open Settings for AU3", 'Your "Open" settings are currently:' & @CRLF & $Open & @CRLF & " But should be:" & @CRLF & $Open_SciTe & @CRLF & @CRLF & " Update?") = 6 Then
        RegWrite("HKCR\AutoIt3Script\Shell\Open\Command", "", "REG_SZ", $Open_SciTe)
        ConsoleWrite('-RegWrite Open $rc = ' & $rc & "  @Error=" & @error & @CRLF)
    EndIf
Else
    ConsoleWrite('+Open already set to default = ' & $Open & @CRLF)
EndIf
; Check Run Settings
If $Run <> $Run_SciTe Then
    If MsgBox(4, "Run Setting for AU3", 'Your "Run" settings are currently:' & @CRLF & $Run & @CRLF & " But should be:" & @CRLF & $Run_SciTe & @CRLF & @CRLF & " Update?") = 6 Then
        RegWrite("HKCR\AutoIt3Script\Shell\Run\Command", "", "REG_SZ", $Run_SciTe)
        ConsoleWrite('-RegWrite Run $rc = ' & $rc & "  @Error=" & @error & @CRLF)
    EndIf
Else
    ConsoleWrite('+Run already set to default = ' & $Run & @CRLF)
EndIf
;Fix default action if needed.
If MsgBox(4, "Default action for AU3", 'Your current "Default" action for au3 is:' & '"' & $Default & '"' &  @CRLF &  @CRLF & "Do you want to change that? ") = 6 Then
    If MsgBox(4, "Default action for AU3", 'Click Yes for "Edit" ' & @CRLF & '    or No for "Run"') = 6 Then
        RegWrite("HKCR\AutoIt3Script\Shell", "", "REG_SZ", "Edit")
        ConsoleWrite('+Changed Default action to "Edit" ' & @CRLF)
    Else
        RegWrite("HKCR\AutoIt3Script\Shell", "", "REG_SZ", "Run")
        ConsoleWrite('+Changed Default action to "Run" ' & @CRLF)
    EndIf
EndIf
;
;Ensure hhctrl is properly registered
$rc = RunWait(@ComSpec & " /c /s regsvr32 hhctrl.ocx", "", @SW_HIDE)
ConsoleWrite('+regsvr32 hhctrl.ocx $rc = ' & $rc & @CRLF)

Edited December 26, 2010 by Jos

[oMBRa]

When I double click on an au3 file, it is not opened nor ran, a window is displayed and it asks me to choose either a program to open the file or to search through the web a program to open it.

I can not even create an au3 file right-clicking on desktop-->New-->New autoit, infact this last voice is missing.

However I have run your script, at the first messagebox (Your current "Default" action for au3 is: "Open" Do you want to change that?) I have chosen Yes, then at the second one (Click Yes for "Edit" or No for "Run") I have clicked on Yes, but the problem is still here.

I think some registry's entries are missing...

[Mat]

Try yashieds File Type Manager (search example scripts), see what that comes up with and build the associations yourself if needs be.

I've never seen this before, and by the sounds of it it's just you so I think you are going to have to built them yourself.

heres what I get:

expandcollapse popup

Windows Registry Editor Version 5.00

[HKEY_CLASSES_ROOT\.AU3]
@="AutoIt3Script"

[HKEY_CLASSES_ROOT\.AU3\ShellNew]
"FileName"="Template.au3"

[HKEY_CLASSES_ROOT\AutoIt3Script]
@="AutoIt v3 Script"

[HKEY_CLASSES_ROOT\AutoIt3Script\DefaultIcon]
@="C:\\Program Files\\AutoIt3\\Icons\\au3script_v10.ico"

[HKEY_CLASSES_ROOT\AutoIt3Script\Shell]
@="Open"

[HKEY_CLASSES_ROOT\AutoIt3Script\Shell\Compile]
@="Compile Script"

[HKEY_CLASSES_ROOT\AutoIt3Script\Shell\Compile\Command]
@="\"C:\\Program Files\\AutoIt3\\Aut2Exe\\Aut2Exe.exe\" /in \"%l\""

[HKEY_CLASSES_ROOT\AutoIt3Script\Shell\Compile with Options]

[HKEY_CLASSES_ROOT\AutoIt3Script\Shell\Compile with Options\Command]
@="\"C:\\Program Files\\AutoIt3\\SciTE\\AutoIt3Wrapper\\AutoIt3Wrapper.exe\" /ShowGui /in \"%l\""

[HKEY_CLASSES_ROOT\AutoIt3Script\Shell\Edit]
@="Edit Script"

[HKEY_CLASSES_ROOT\AutoIt3Script\Shell\Edit\Command]
@="\"C:\\Program Files\\AutoIt3\\SciTE\\SciTE.exe\" \"%1\""

[HKEY_CLASSES_ROOT\AutoIt3Script\Shell\Open]
@="Open"

[HKEY_CLASSES_ROOT\AutoIt3Script\Shell\Open\Command]
@="\"C:\\Program Files\\AutoIt3\\SciTE\\SciTE.exe\" \"%1\""

[HKEY_CLASSES_ROOT\AutoIt3Script\Shell\Run]
@="Run Script"

[HKEY_CLASSES_ROOT\AutoIt3Script\Shell\Run\Command]
@="\"C:\\Program Files\\AutoIt3\\AutoIt3.exe\" \"%1\" %*"

[HKEY_CLASSES_ROOT\AutoIt3Script\Shell\Tidy]

[HKEY_CLASSES_ROOT\AutoIt3Script\Shell\Tidy\Command]
@="\"C:\\Program Files\\AutoIt3\\SciTE\\Tidy\\Tidy.exe\" \"%1\""

[trancexx]

I saw this few times. The solution was very simple and registry was just fine btw. I just had to right click on some script, then go to properties and click on Change... button. Then regardless of any setting in the new pop-up window click Browse... button and locate AutoIt exe, select it and not forget to click OK on all windows (this was crucial naturally). Everything was fixed momentarily.

This is bullet-proof solution for this particular problem (explorer's), but people usually fail to follow these few simple steps in order to fix the issue.

Mat we are on AutoIt forum and on top of that Jos posted what he posted.

[oMBRa]

I think I have solved the problem, I had to disable the UAC, (in case you ask me, yes, I was running the installers as administrator).

@trancexx

Thanks for reminding me that easy solution, however I prefer to find what causes the problem first rather than applying a solution that partially solves it.

[fmaione]

Hello, on my Windows 7 Enterprise I've fixed the problem setting HKEY_CLASSES_ROOT\.au3\(Default) to "AutoIt3Script".

Maybe there is an issue in the installer?