how do i use ispressed to call a function just once

[rmkbow]

How would I go about using ispressed to call a function only once. But after the button is de-pressed, it is immediately available again.

or is this not possible.

[Varian]

#include <Misc.au3>
$Dll = DllOpen("user32.dll")
Global $MyFunctionHasBeenRun = False

;some code

If _IsPressed(01, $Dll) Then _MyFunction()  ;left mousae button clicked

Func _MyFunction()
    If $MyFunctionHasBeenRun Then Return    ;skips function if Flag is True
    ;som code
    $MyFunctionHasBeenRun = True    ;sets Flag to True so function will not run again
EndFunc

[Tvern]

Varian pretty much answered this, but as I made the examples:

Blocking version:

#include <misc.au3>
Global $DLLUser32 = DllOpen("user32.dll")

While 1
    If _IsPressed("01", $DLLUser32) Then _TestFunc()
    ConsoleWrite(".") ;dots indicate the main loop is looping
    Sleep(100)
WEnd

Func _TestFunc()
    ConsoleWrite(@CRLF & "_TestFunc()!" & @CRLF)
    While _IsPressed("01", $DLLUser32)
        Sleep(20)
    WEnd
EndFunc

non-blocking:

#include <misc.au3>
Global $fRun
Global $DLLUser32 = DllOpen("user32.dll")

While 1
    If _IsPressed("01", $DLLUser32) Then
        If $fRun Then
            _TestFunc()
            $fRun = False
        EndIf
    Else
        $fRun = True
    EndIf
    ConsoleWrite(".")  ;dots indicate the main loop is looping
    Sleep(100)
WEnd

Func _TestFunc()
    ConsoleWrite(@CRLF & "_TestFunc()!" & @CRLF)
EndFunc

[rmkbow]

ah, awesome. I didn`t think of implementing it like that. Thanks.