Yet Another "incorrect number of subscripts or subscript"

[BillAlso]

I know it's simple but after two days of searching and trying, I have to admit defeat.

Examples of displaying an array in a ListBox usually create the array from a for...next loop. Here, I load the array from a _FileReadToArray function, create a GUI window, a ListView, check if I actually have an array with _ArrayDisplay, then pass it off to _GUICtrlListView_AddArray. Works fine but when I reach the _GUICtrlListView_AddArray, I get the infamous "Array variable has incorrect number of subscripts or subscript dimension range exceeded." There is some tiny thing I'm overlooking but just can't get what it is.

Thanks in advance,

Bill

expandcollapse popup

#cs ----------------------------------------------------------------------------

 AutoIt Version: 3.3.6.1

 Script Function:
    Trying to load a file into an array, then into a ListBox
    Title:  Heavily modified Melba's Array to Listbox routine.

#ce ----------------------------------------------------------------------------

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Include <GuiListView.au3>
#include <file.au3>
#include <array.au3>


Local $aArray, $hListView, $hGui

; Read file into an array.
; tfm01.txt is a 10 line text file created in Notepad that says: "One, two, three" etc.
If Not _FileReadToArray("tfm01.txt",$aArray) Then
   MsgBox(4096,"Error", " Error reading log to Array     error:" & @error)
   Exit
EndIf

; Create GUI Window
$hGUI = GUICreate(" Test of Load File into Listbox", 500, 410)

; Create listview
$hListView = GUICtrlCreateListView("File Array", 2, 2, 490, 400)

_GUICtrlListView_SetItemCount($hListView, $aArray[0])

; Show we have an array loaded and the number of elements
_ArrayDisplay ($aArray)

; Put array into ListView
_GUICtrlListView_AddArray($hListView, $aArray)

;==== ...THEN THE GUI ELEMENTS ARE DISPLAYED WITH THIS LINE.
GUISetState()

MsgBox (1, "","")

[BrewManNH]

As written, the _GUICtrlListView_AddArray requires a 2D array, a 1D array causes that error. The documentation for the function doesn't mention that though. I ran into this problem myself a little while ago and found out the hard way.

[Melba23]

BillAlso,

Welcome to the AutoIt forum.

There is a nasty little surprise hidden in the _GUICtrlListView_AddArray function - which is not mine by the way.

You need to declare the array with 2 dimensions - even if (as in this case) you only have a single column. I have not investigated, but I would guess this is no doubt to do with the internal workings of the UDF - I remember having to put in lots of checks in my GUIListViewEx UDF so that I did not have the same limitation.

So you need to transfer your elements from the 1D array you get from _FileReadToArray into a 2D array to pass to the UDF. Here is how you might do it - look for the <<<<<<<<<<<<<< lines:

expandcollapse popup

#cs ----------------------------------------------------------------------------

 AutoIt Version: 3.3.6.1

 Script Function:
    Trying to load a file into an array, then into a ListBox
    Title:  Heavily modified Melba's Array to Listbox routine.

#ce ----------------------------------------------------------------------------

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Include <GuiListView.au3>
#include <file.au3>
#include <array.au3>


Local $aArray, $hListView, $hGui

; Read file into an array.
; tfm01.txt is a 10 line text file created in Notepad that says: "One, two, three" etc.
If Not _FileReadToArray("tfm01.txt",$aArray) Then
   MsgBox(4096,"Error", " Error reading log to Array     error:" & @error)
   Exit
EndIf

; Create GUI Window
$hGUI = GUICreate(" Test of Load File into Listbox", 500, 410)

; Create listview
$hListView = GUICtrlCreateListView("File Array", 2, 2, 490, 400)

_GUICtrlListView_SetItemCount($hListView, $aArray[0])

; Show we have an array loaded and the number of elements
_ArrayDisplay ($aArray)

; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
Global $aNewArray[$aArray[0]][1]
For $i = 1 To $aArray[0]
    $aNewArray[$i - 1][0] = $aArray[$i]
Next

_ArrayDisplay($aNewArray)
; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<

; Put array into ListView
_GUICtrlListView_AddArray($hListView, $aNewArray) ; <<<<<<<<<<<<<<<<<
;==== ...THEN THE GUI ELEMENTS ARE DISPLAYED WITH THIS LINE.
GUISetState()

MsgBox (1, "","")

It is interesting to see that there is no visual difference between the 2 arrays in _ArrayDisplay even though one is 1D and the other is 2D. However, declaring single-column 2D arrays is a useful trick from time to time.

All clear?

M23

[BillAlso]

BrewMan and Melba, thanks much for saving me from "the home". Really thought I was loosing it, there. And, Melba, thanks for the workaround; that really nailed what is going on.

So: does this constitute a bug in _GUICtrlListView_AddArray or is that a feature, as in being necessary for the control to work properly in other cases?

Bill

[BrewManNH]

As Microsoft would explain it, it's an undocumented feature. I believe it's because the UDF function is expecting sub-items in the array and wasn't designed to handle a listview with a single column.